Pensieve Header: Plotting 2-variable polynomials.

Print["Loading PolyPlot.m from http://drorbn.net/ubc24/ap to plot 2-variable polynomials."]

PolyPlot[{Δ_,θ_}]:=Module[{crs,m,m1,m2,maxc,minc,s,rect,hex},GraphicsColumn[{
rect={{0,0},{1,0},{1,1},{0,1}};
hex=Table[{Cos[α],Sin[α]}/Cos[2π/12]/2, {α,2π/12,2π,2π/6}];
If[Expand[Δ]===0,Graphics[],
m=Max[-Exponent[Δ,T,Min], Exponent[Δ,T,Max]];
crs=CoefficientRules[(T^m)Δ,{T}];
maxc=N@Log@Max@Abs[Last/@crs];
minc=N@Log@Min@Select[Abs[Last/@crs],#>0&];
If[minc==maxc,s[_]=0,s[c_]:=s[c]=(maxc-Log@c)/(maxc-minc)];
Graphics[crs/.({x_}->c_):>{
Lighter[Which[c==0, White,c>0, Red,c<0,Blue], 0.88s[Abs@c]],
Tooltip[Polygon[({x+m-1/2,0}+#)&/@rect],c]
},AspectRatio->Min[1/5 ,1/(Sqrt[m+1])],ImagePadding->None,PlotRangePadding->None]
],
If[Expand[θ]===0,Graphics[{White,Disk[]}],
m1=Max[-Exponent[θ,(Subscript[T, 1]),Min], Exponent[θ,(Subscript[T, 1]),Max]];
m2=Max[-Exponent[θ,(Subscript[T, 2]),Min], Exponent[θ,(Subscript[T, 2]),Max]];
crs=CoefficientRules[(Subscript[T, 1]^m1)(Subscript[T, 2]^m2)θ,{(Subscript[T, 1]),(Subscript[T, 2])}];
maxc=N@Log@Max@Abs[Last/@crs];
minc=N@Log@Min@Select[Abs[Last/@crs],#>0&];
If[minc==maxc,s[_]=0,s[c_]:=s[c]=(maxc-Log@c)/(maxc-minc)];
Graphics[{{White,Disk[{0,0},1+Cos[2π/12]Norm[{m1,m2}]/(Sqrt[2])]},
crs/.({x1_,x2_}->c_):>{
Lighter[Which[c==0, White,c>0, Red,c<0,Blue], 0.88s[Abs@c]],
Tooltip[Polygon[((({{1, -1/2}, {0, (Sqrt[3])/2}})).{x1-m1,x2-m2}+#)&/@hex],c] 
}
},ImagePadding->None,PlotRangePadding->None]
]
},Spacings -> Scaled@0.08,ImagePadding->None,PlotRangePadding->None]];

PolyPlot@{-1+(1/T)+T,-(1/(Subscript[T, 1]^2))-(Subscript[T, 1]^2)-(1/(Subscript[T, 2]^2))-(1/((Subscript[T, 1]^2) (Subscript[T, 2]^2)))+(1/((Subscript[T, 1]) (Subscript[T, 2]^2)))+(1/((Subscript[T, 1]^2) (Subscript[T, 2])))+((Subscript[T, 1])/(Subscript[T, 2]))+((Subscript[T, 2])/(Subscript[T, 1]))+(Subscript[T, 1]^2) (Subscript[T, 2])-(Subscript[T, 2]^2)+(Subscript[T, 1]) (Subscript[T, 2]^2)-(Subscript[T, 1]^2) (Subscript[T, 2]^2)}