Pensieve header: A talk and a program about Archibald- ($\mathcal A$-) and $\Gamma$-calculus and the Halacheva map between them; the $\mathcal A$ part. Continues pensieve://2021-03/

𝒜-Calculus

\begin{frame}
{\LARGE 3. An Implementation of $\calA$}
If I didn’t implement I wouldn’t believe myself.
\vskip 2mm
Written in Mathematica~\cite{Wolfram:Mathematica}, available as the notebook {\tt Alpha.nb} at \url{http://drorbn.net/mo21/ap}. Code lines are highlighted in grey, demo lines are plain.
We start with an implementation of elements (``{\tt Wedge}’’) of exterior algebras, and of the wedge product (``{\tt WP}’’):
\vskip 2mm

WP[Wedge[u___],Wedge[v___]]:=Signature[{u,v}]*Wedge@@Sort[{u,v}];
WP[0,_]=WP[_,0]=0;
WP[A_,B_]:=Expand[Distribute[A ** B] /. (a_. * u_Wedge) ** (b_. * v_Wedge):>a b WP[u,v]];

WP[Wedge[]+Wedge[a]-2b⋀a, Wedge[]-3Wedge[b]+7c⋀d]

\end{frame}
\begin{frame}\null
We then define the exponentiation map in exterior algebras (``{\tt WExp}’’) by summing the series and stopping the sum once the current term (``{\tt t}’’) vanishes:

WExp[A_]:=Module[{s=Wedge[],t=Wedge[],k=0},
While[t=!=0,s+=(t=Expand[WP[t,A]/(++k)])]; s]

WExp[a⋀b+c⋀d+e⋀f]

\end{frame}
\begin{frame}\null
Contractions!

(Subscript[c, x_,y_])[w_Wedge]:=Module[{i,j},
{i}=FirstPosition[w,x,{0}]; {j}=FirstPosition[w,y,{0}];
(Piecewise[{{w, (i==0)∧(j==0)}, {(((-1))^(i+j+If[i>j,0,1]))Delete[w,{{i},{j}}], (i>0)∧(j>0)}}])
];
(Subscript[c, x_,y_])[ℰ_]:=ℰ/.w_Wedge:>(Subscript[c, x,y])[w]

WExp[a⋀b+2c⋀d]
(Subscript[c, d,c])@WExp[a⋀b+2c⋀d]

\end{frame}

\begin{frame}
\parpic[r]{\def\X{$X_{ijkl}[S,T]$} \input{figs/Xp.pdf_t}}
$\calA${\tt [is,os,cs,w]} is also a container for the values of the $\calA$-invariant of a tangle. In it, {\tt is} are the labels of the input strands, {\tt os} are the labels of the output strands, {\tt cs} is an assignment of colours (namely, variables) to all the ends $\{\xi_i\}_{i\in\text{\tt is}}\sqcup\{x_j\}_{j\in\text{\tt os}}$, and {\tt w} is the ``payload’’: an element of $\Lambda\left(\{\xi_i\}_{i\in\text{\tt is}}\sqcup\{x_j\}_{j\in\text{\tt os}}\right)$.

𝒜[(Subscript[X, i_,j_,k_,l_])[S_,T_]]:=𝒜[{l,i},{j,k},\[LeftAssociation](Subscript[ξ, i])->S,(Subscript[x, j])->T,(Subscript[x, k])->S,(Subscript[ξ, l])->T\[RightAssociation],Expand[(T^(-1/2))WExp[Expand[{(Subscript[ξ, l]),(Subscript[ξ, i])}.(({{1, 1-T}, {0, T}})).{(Subscript[x, j]),(Subscript[x, k])}]/.(Subscript[ξ, a_])(Subscript[x, b_]):>(Subscript[ξ, a])⋀(Subscript[x, b])]]];

𝒜[(Subscript[X, 1,2,3,4])[u,v]]

𝒜[(Subscript[X, i_,j_,k_,l_])]:=𝒜[(Subscript[X, i,j,k,l])[(Subscript[τ, i]),(Subscript[τ, l])]]

\end{frame}

\begin{frame}\null
The negative crossing and the ``point’’:
\[ \def\Xbar{$\bar{X}_{ijkl}[S,T]$}  \def\P{$P_{ij}[T]$}
  \input{figs/XmP.pdf_t}
\]

𝒜[(Subscript[(OverBar[X]), i_,j_,k_,l_])[S_,T_]]:=𝒜[{i,j},{k,l},\[LeftAssociation](Subscript[ξ, i])->S,(Subscript[ξ, j])->T,(Subscript[x, k])->S,(Subscript[x, l])->T\[RightAssociation],Expand[(T^(1/2))WExp[Expand[{(Subscript[ξ, i]),(Subscript[ξ, j])}.(({{(T^(-1)), 0}, {1-(T^(-1)), 1}})).{(Subscript[x, k]),(Subscript[x, l])}]/.(Subscript[ξ, a_])(Subscript[x, b_]):>(Subscript[ξ, a])⋀(Subscript[x, b])]]];
𝒜[(Subscript[(OverBar[X]), i_,j_,k_,l_])]:=𝒜[(Subscript[(OverBar[X]), i,j,k,l])[(Subscript[τ, i]),(Subscript[τ, j])]];

𝒜[(Subscript[P, i_,j_])[T_]]:=𝒜[{i},{j},\[LeftAssociation](Subscript[ξ, i])->T,(Subscript[x, j])->T\[RightAssociation],WExp[(Subscript[ξ, i])⋀(Subscript[x, j])]];
𝒜[(Subscript[P, i_,j_])]:=𝒜[(Subscript[P, i,j])[(Subscript[τ, i])]]

\end{frame}
\begin{frame}\null
The linear structure on $\calA$’s:

𝒜/:α_×𝒜[is_,os_,cs_,w_]:=𝒜[is,os,cs,Expand[α w]]
𝒜/:𝒜[is1_,os1_,cs1_,w1_]+𝒜[is2_,os2_,cs2_,w2_]/;(Sort@is1==Sort@is2)∧(Sort@os1==Sort@os2)∧(Sort@Normal@cs1==Sort@Normal@cs2):=𝒜[is1,os1,cs1,w1+w2]

Deciding if two $\calA$’s are equal:

𝒜/:𝒜[is1_,os1_,_,w1_]≡𝒜[is2_,os2_,_,w2_]:=TrueQ[(Sort@is1===Sort@is2)∧(Sort@os1===Sort@os2)∧PowerExpand[w1==w2]]

\end{frame}
\begin{frame}\null
\vskip -12mm
\null\hfill\smash{\imagetop{\input{figs/R2Left.pdf_t}}}
\newline The union operation on $\calA$’s (implemented as ``multiplication’’):

𝒜/:𝒜[is1_,os1_,cs1_,w1_]𝒜[is2_,os2_,cs2_,w2_]:=𝒜[is1⋃is2,os1⋃os2,Join[cs1,cs2],WP[w1,w2]]

Short[𝒜[(Subscript[X, 2,4,3,1])[S,T]]𝒜[(Subscript[(OverBar[X]), 3,4,6,5])],5]

\end{frame}
\begin{frame}\null
Contractions of $\calA$-objects:

(Subscript[c, h_,t_])@𝒜[is_,os_,cs_,w_]:=𝒜[
DeleteCases[is,t],DeleteCases[os,h],KeyDrop[cs,{(Subscript[x, h]),(Subscript[ξ, t])}],(Subscript[c, (Subscript[x, h]),(Subscript[ξ, t])])[w]
] /. If[MatchQ[cs[(Subscript[ξ, t])],(Subscript[τ, _])], cs[(Subscript[ξ, t])]->cs[(Subscript[x, h])],cs[(Subscript[x, h])]-> cs[(Subscript[ξ, t])]];

(Subscript[c, 4,4])[𝒜[(Subscript[X, 2,4,3,1])[S,T]]𝒜[(Subscript[(OverBar[X]), 3,4,6,5])]]

\end{frame}
\begin{frame}\null
Automatic and intelligent multiple contractions:

c@𝒜[is_,os_,cs_,w_]:=Fold[(Subscript[c, #2,#2])[#1]&,𝒜[is,os,cs,w],is⋂os]
𝒜[{A_𝒜}]:=c[A];
𝒜[{A1_𝒜,As__𝒜}]:=Module[{A2},
A2=First@MaximalBy[{As},Length[A1[[1]]⋂#[[2]]]+Length[A1[[2]]⋂#[[1]]]&];
𝒜[Join[{c[A1 A2]}, DeleteCases[{As},A2]]] ]
𝒜[𝒪s_List]:=𝒜[𝒜/@𝒪s]

c[𝒜[(Subscript[X, 2,4,3,1])[S,T]]𝒜[(Subscript[(OverBar[X]), 3,4,6,5])]]

𝒜@{𝒜[(Subscript[X, 2,4,3,1])[S,T]],𝒜[(Subscript[(OverBar[X]), 3,4,6,5])]}

\end{frame}

Skein Relations

\begin{frame}{\LARGE 4. Skein relations and evaluations for $\calA$}
\[ \input{figs/SimpleTangle.pdf_t} \]

𝒜@{(Subscript[(OverBar[X]), 4,1,6,3])[v,u],(Subscript[(OverBar[X]), 3,2,5,4])}

Reidemeister 2

\end{frame}
\begin{frame}{\large Reidemeister 2}

\[ \input{figs/R2.pdf_t} \]

𝒜@{(Subscript[X, 2,4,3,1])[S,T],(Subscript[(OverBar[X]), 3,4,6,5])}≡𝒜@{(Subscript[P, 1,5])[T],(Subscript[P, 2,6])[S]}

𝒜@{(Subscript[(OverBar[X]), 3,1,2,4])[S,T],(Subscript[X, 6,5,3,4])}≡𝒜@{(Subscript[P, 1,5])[T],(Subscript[P, 6,2])[S]}

Reidemeister 3

\end{frame}
\begin{frame}{\large Reidemeister 3}

\[ \input{figs/R3.pdf_t} \]

𝒜@{(Subscript[X, 2,5,4,1])[(Subscript[T, 2]),(Subscript[T, 1])],(Subscript[X, 3,7,6,5])[(Subscript[T, 3]),(Subscript[T, 1])],(Subscript[X, 6,9,8,4])}≡𝒜@{(Subscript[X, 3,5,4,2])[(Subscript[T, 3]),(Subscript[T, 2])],(Subscript[X, 4,6,8,1])[(Subscript[T, 3]),(Subscript[T, 1])],(Subscript[X, 5,7,9,6])}

\end{frame}

Reidemeister 1

\begin{frame}{\large Reidemeister 1}
\[ \def\p{$=\tau_1^{1/2}$} \def\m{$=\tau_1^{-1/2}$} \input{figs/R1.pdf_t} \]

{𝒜@{(Subscript[X, 3,3,2,1])}≡(Subscript[τ, 1]^(-1/2))𝒜@{(Subscript[P, 1,2])}, 𝒜@{(Subscript[X, 1,2,3,3])}≡(Subscript[τ, 1]^(1/2))𝒜@{(Subscript[P, 1,2])}, 𝒜@{(Subscript[(OverBar[X]), 1,3,3,2])}≡(Subscript[τ, 1]^(-1/2))𝒜@{(Subscript[P, 1,2])}, 𝒜@{(Subscript[(OverBar[X]), 3,1,2,3])}≡(Subscript[τ, 1]^(1/2))𝒜@{(Subscript[P, 1,2])}}

(So we have an invariant, up to rotation numbers).
\end{frame}

The Relation with the Multivariable Alexander Polynomial

\begin{frame}{\large The Relation with the Multivariable Alexander Polynomial}
\[ \input{figs/Borromean.pdf_t} \]

MVA=(u^(-1/2))(v^(-1/2))(w^(-1/2))(u-1) (v-1) (w-1);

A={(Subscript[(OverBar[X]), 1,12,2,13])[u,v],(Subscript[(OverBar[X]), 13,2,6,3]),(Subscript[X, 8,4,9,3]),(Subscript[X, 4,10,5,9]),(Subscript[X, 6,17,7,16])[v,w],
(Subscript[X, 15,8,16,7]),(Subscript[(OverBar[X]), 14,10,15,11]),(Subscript[(OverBar[X]), 11,17,12,14])}//𝒜//Last//Factor

A==(u^(-1/2))(u-1)(u^0)(v^(-1/2))(w^(1/2))MVA(Wedge[]-(Subscript[x, 5])⋀(Subscript[ξ, 1]))

\end{frame}

Overcrossings Commute but Undercrossings don’t

\begin{frame}{\large Overcrossings Commute but Undercrossings don't}

\[ \input{figs/OUC.pdf_t} \]

𝒜@{(Subscript[X, 2,7,5,1]),(Subscript[X, 3,4,6,7])}≡𝒜@{(Subscript[X, 3,7,6,1]),(Subscript[X, 2,4,5,7])}

𝒜@{(Subscript[(OverBar[X]), 1,2,7,5]),(Subscript[(OverBar[X]), 7,3,4,6])}≡𝒜@{(Subscript[(OverBar[X]), 1,3,7,6]),(Subscript[(OverBar[X]), 7,2,4,5])}

\end{frame}

The Conway Relation

\begin{frame}{\large The Conway Relation\hfill (see~\cite{Conway:Enumeration})}
\[ \input{figs/Conway.pdf_t} \]

𝒜@{(Subscript[X, 2,3,4,1])[T,T]} - 𝒜@{(Subscript[(OverBar[X]), 1,2,3,4])[T,T]}≡((T^(-1/2))-(T^(1/2)))𝒜@{(Subscript[P, 1,4])[T],(Subscript[P, 2,3])[T]}

\[ \includegraphics[height=36mm]{../../Projects/Gallery/Conway.png} \]
\end{frame}

Conway’s Second Set of Identities

\begin{frame}{\large Conway’s Second Set of Identities\hfill (see~\cite{Conway:Enumeration})}
\[ \def\b{$=((uv)^{1/2}+(uv)^{-1/2})$} \def\c{$=((u/v)^{1/2}+(u/v)^{-1/2})$} \input{figs/Conway2nd.pdf_t} \]

𝒜@{(Subscript[X, 2,4,3,1])[v,u],(Subscript[X, 4,6,5,3])} + 𝒜@{(Subscript[(OverBar[X]), 1,2,4,3])[u,v],(Subscript[(OverBar[X]), 3,4,6,5])}≡((u^(1/2))(v^(1/2))+(u^(-1/2))(v^(-1/2)))𝒜@{(Subscript[P, 1,5])[u],(Subscript[P, 2,6])[v]}

𝒜@{(Subscript[(OverBar[X]), 4,1,6,3])[v,u],(Subscript[(OverBar[X]), 3,2,5,4])} + 𝒜@{(Subscript[X, 1,6,3,4])[u,v],(Subscript[X, 2,5,4,3])}≡((u^(1/2))(v^(-1/2))+(u^(-1/2))(v^(1/2)))𝒜@{(Subscript[P, 1,5])[u],(Subscript[P, 2,6])[v]}

\end{frame}

\begin{frame}\null
{\bf Virtual versions} (Archibald,~\cite{Archibald:Thesis})
\[ \def\b{$=(\tau_1^{1/2}+\tau_1^{-1/2})$} \def\c{$=(\tau_2^{1/2}+\tau_2^{-1/2})$} \input{figs/Conway2ndV.pdf_t} \]

𝒜@{(Subscript[X, 2,3,4,1])} + 𝒜@{(Subscript[(OverBar[X]), 2,1,4,3])}≡((Subscript[τ, 1]^(1/2))+(Subscript[τ, 1]^(-1/2)))𝒜@{(Subscript[P, 1,3]),(Subscript[P, 2,4])}

𝒜@{(Subscript[(OverBar[X]), 1,2,3,4])} + 𝒜@{(Subscript[X, 1,4,3,2])}≡((Subscript[τ, 2]^(1/2))+(Subscript[τ, 2]^(-1/2)))𝒜@{(Subscript[P, 1,3]),(Subscript[P, 2,4])}

\end{frame}

Conway’s Third Identity

\begin{frame}{\large Conway’s Third Identity \hfill (see~\cite{Conway:Enumeration})}
\[ \input{figs/C3.pdf_t} \]

𝒜@{(Subscript[X, 6,4,9,1]),(Subscript[(OverBar[X]), 4,5,7,8]),(Subscript[(OverBar[X]), 2,3,5,6])} + 𝒜@{(Subscript[X, 2,4,5,1]),(Subscript[(OverBar[X]), 4,3,7,6]),(Subscript[X, 6,8,9,5])}≡𝒜@{(Subscript[(OverBar[X]), 1,6,4,9]),(Subscript[X, 5,7,8,4]),(Subscript[X, 3,5,6,2])} + 𝒜@{(Subscript[(OverBar[X]), 1,2,4,5]),(Subscript[X, 3,7,6,4]),(Subscript[(OverBar[X]), 5,6,8,9])}

\end{frame}

\begin{frame}\null
{\bf Virtual version} (Archibald,~\cite{Archibald:Thesis})
\[ \input{figs/C3V.pdf_t} \]

𝒜@{(Subscript[X, 3,7,6,1]),(Subscript[(OverBar[X]), 7,2,4,5])} + 𝒜@{(Subscript[X, 2,4,7,1]),(Subscript[X, 3,5,6,7])}≡𝒜@{(Subscript[X, 3,7,6,2]),(Subscript[X, 7,4,5,1])} + 𝒜@{(Subscript[(OverBar[X]), 1,2,7,5]),(Subscript[X, 3,4,6,7])}

\end{frame}

Jun Murakami’s Fifth Axiom

\begin{frame}{\large Jun Murakami’s Fifth Axiom \hfill (see~\cite{MurakamiJ:StateModel})}
\[ \def\prop{$=\frac{\sqrt{S}(1-T)}{\sqrt{T}}$} \input{figs/MJ5.pdf_t} \]

𝒜@{(Subscript[X, 1,4,2,5])[T,S],(Subscript[X, 4,3,5,2])} ≡(((Sqrt[S])(1-T))/(Sqrt[T]))𝒜@{(Subscript[P, 1,3])[T]}

\[ \includegraphics[height=20mm]{../../Projects/Gallery/MurakamiJ.jpg} \]
\end{frame}

\begin{frame}\null
{\bf Virtual versions} (Archibald,~\cite{Archibald:Thesis})
\[ \def\prop{$=(T^{-1/2}-T^{1/2})$} \input{figs/MJ5V.pdf_t} \]

𝒜@{(Subscript[X, 3,2,3,1])[S,T]} ≡((T^(-1/2))-(T^(1/2)))𝒜@{(Subscript[P, 1,2])[T]}

𝒜@{(Subscript[X, 1,3,2,3])}

\end{frame}

Jun Murakami’s Third Axiom

\begin{frame} {\large Jun Murakami’s Third Axiom\hfill(see~\cite{MurakamiJ:StateModel})}
\[ \scalebox{0.64}{\input{figs/Murakami3.pdf_t}} \]

(Subscript[𝒜, 2112])=𝒜@{(Subscript[X, 3,8,7,2]),(Subscript[X, 7,10,9,1]),(Subscript[X, 10,11,4,9]),(Subscript[X, 8,6,5,11])};
(Subscript[𝒜, 1221])=𝒜@{(Subscript[X, 2,8,7,1]),(Subscript[X, 3,10,9,8]),(Subscript[X, 10,6,11,9]),(Subscript[X, 11,5,4,7])};
(Subscript[𝒜, 2211])=𝒜@{(Subscript[X, 3,8,7,2]),(Subscript[X, 8,6,9,7]),(Subscript[X, 9,11,10,1]),(Subscript[X, 11,5,4,10])};
(Subscript[𝒜, 1122])=𝒜@{(Subscript[X, 2,8,7,1]),(Subscript[X, 8,9,4,7]),(Subscript[X, 3,11,10,9]),(Subscript[X, 11,6,5,10])};
(Subscript[𝒜, 11])=𝒜@{(Subscript[X, 2,8,7,1]),(Subscript[X, 8,5,4,7]),(Subscript[P, 3,6])};  (Subscript[𝒜, 22])=𝒜@{(Subscript[X, 3,8,7,2]),(Subscript[X, 8,6,5,7]),(Subscript[P, 1,4])};
(Subscript[𝒜, ∅])=𝒜@{(Subscript[P, 1,4]),(Subscript[P, 2,5]),(Subscript[P, 3,6])};
(SubPlus[g])[z_]:=(z^(1/2))+(z^(-1/2)); (SubMinus[g])[z_]:=(z^(1/2))-(z^(-1/2));
(SubPlus[g])[(Subscript[τ, 1])](SubMinus[g])[(Subscript[τ, 2])](Subscript[𝒜, 2112])-(SubMinus[g])[(Subscript[τ, 2])](SubPlus[g])[(Subscript[τ, 3])](Subscript[𝒜, 1221])-(SubMinus[g])[(Subscript[τ, 3])/(Subscript[τ, 1])]((Subscript[𝒜, 2211])+(Subscript[𝒜, 1122]))+(SubMinus[g])[(Subscript[τ, 2])(Subscript[τ, 3])/(Subscript[τ, 1])](SubPlus[g])[(Subscript[τ, 3])](Subscript[𝒜, 11])-(SubPlus[g])[(Subscript[τ, 1])](SubMinus[g])[(Subscript[τ, 1])(Subscript[τ, 2])/(Subscript[τ, 3])](Subscript[𝒜, 22])≡(SubMinus[g])[(Subscript[τ, 3]^2)/(Subscript[τ, 1]^2)](Subscript[𝒜, ∅])

\end{frame}

The Naik-Stanford Double Delta Move

\begin{frame}{\large The Naik-Stanford Double Delta Move\hfill(see~\cite{NaikStanford:Move})}
\vskip -5mm
\[
  \includegraphics[height=20mm]{../../Projects/Gallery/Naik.jpg}
  \qquad\scalebox{0.8}{\input{figs/NaikStanford.pdf_t}}\qquad
  \includegraphics[height=20mm]{../../Projects/Gallery/Stanford.jpg}
\]

=

Timing[𝒜@{(Subscript[X, 6,10,28,24])[w,v],(Subscript[(OverBar[X]), 28,3,29,19])[w,v],(Subscript[X, 26,20,27,19])[w,v],(Subscript[(OverBar[X]), 27,23,11,24])[w,v],
(Subscript[X, 1,12,13,30])[u,w],(Subscript[(OverBar[X]), 13,5,14,25])[u,w],(Subscript[X, 17,26,18,25])[u,w],(Subscript[(OverBar[X]), 18,29,8,30])[u,w],
(Subscript[X, 4,7,22,15])[v,u],(Subscript[(OverBar[X]), 22,2,23,16])[v,u],(Subscript[X, 20,17,21,16])[v,u],(Subscript[(OverBar[X]), 21,14,9,15])[v,u]}≡𝒜@{(Subscript[X, 5,9,25,21])[w,v],(Subscript[(OverBar[X]), 25,4,26,22])[w,v],(Subscript[X, 29,23,30,22])[w,v],(Subscript[(OverBar[X]), 30,20,12,21])[w,v],
(Subscript[X, 2,11,16,27])[u,w],(Subscript[(OverBar[X]), 16,6,17,28])[u,w],(Subscript[X, 14,29,15,28])[u,w],(Subscript[(OverBar[X]), 15,26,7,27])[u,w],
(Subscript[X, 3,8,19,18])[v,u],(Subscript[(OverBar[X]), 19,1,20,13])[v,u],(Subscript[X, 23,14,24,13])[v,u],(Subscript[(OverBar[X]), 24,17,10,18])[v,u]}]

\end{frame}

\begin{frame}\null
{\bf Virtual Version 1} (Archibald,~\cite{Archibald:Thesis})

\[ \input{figs/VNS1.pdf_t} \]

𝒜@{(Subscript[X, 1,8,11,3])[u,v],(Subscript[(OverBar[X]), 11,2,12,7])[u,v],(Subscript[X, 12,10,13,4])[u,w],(Subscript[(OverBar[X]), 13,5,6,9])[u,w]} ≡𝒜@{(Subscript[X, 1,10,11,4])[u,w],(Subscript[(OverBar[X]), 11,5,12,9])[u,w],(Subscript[X, 12,8,13,3])[u,v],(Subscript[(OverBar[X]), 13,2,6,7])[u,v]}

\end{frame}

\begin{frame}\null
{\bf Virtual Version 2} (Archibald,~\cite{Archibald:Thesis})

\[ \input{figs/VNS2.pdf_t} \]

𝒜@{(Subscript[(OverBar[X]), 20,1,10,13])[v,u],(Subscript[X, 3,14,19,13])[v,u],(Subscript[X, 14,11,15,21])[u,w],(Subscript[(OverBar[X]), 15,6,7,22])[u,w],
(Subscript[X, 2,12,16,22])[u,w],(Subscript[(OverBar[X]), 16,5,17,21])[u,w], (Subscript[(OverBar[X]), 19,17,9,18])[v,u],(Subscript[X, 4,8,20,18])[v,u]}≡𝒜@{(Subscript[X, 1,11,13,21])[u,w],(Subscript[(OverBar[X]), 13,6,14,22])[u,w],(Subscript[(OverBar[X]), 20,14,10,15])[v,u],(Subscript[X, 3,7,19,15])[v,u],
(Subscript[(OverBar[X]), 19,2,9,16])[v,u],(Subscript[X, 4,17,20,16])[v,u],(Subscript[X, 17,12,18,22])[u,w],(Subscript[(OverBar[X]), 18,5,8,21])[u,w]}

\end{frame}