Pensieve header: Knot Signatures via the Goeritz Matrix.

SetDirectory["C:\\drorbn\\AcademicPensieve\\Projects\\Signatures"];
<< Common.m

Knot Signatures Using the Goeritz Matrix

Formulas follow Gordon-Litherland. For checkerboard colouring, the region to the right of an odd-numbered arc is declared to be black.

μ[K_] :=Plus@@(PD[K]/.x_X:>{PositiveQ@x,OddQ@x[[1]]} /. {
{True,True}->0,{True,False}->1,{False,True}->-1,{False,False}->0
});

μ/@AllKnots[{3,7}]

Signature from Goeritz

\includegraphics[width=\linewidth]{GoeritzConventions.pdf}

GoeritzSignature[K_]:=Module[{m=0,a,c=0,ds,cs,is,A},
ds=List@@PD[K]/.x:X[i_,j_,k_,l_]:>If[PositiveQ@x,
If[OddQ@i,{(Subscript[a, -i,l])[++c](Subscript[a, k,-j])[++c],-1},
{(Subscript[a, j,i])[++c](Subscript[a, -l,-k])[++c],++m;1}],
If[OddQ@i,{(Subscript[a, -i,-l])[++c](Subscript[a, k,j])[++c],--m;-1},
{(Subscript[a, -j,i])[++c](Subscript[a, l,-k])[++c],1}]];
cs=Times@@ds[[All,1]]//.(Subscript[a, i_,j_])[x__](Subscript[a, j_,k_])[y__]:>(Subscript[a, i,k])[x,y]/.(Subscript[a, __])[x__]:>a[x];
A=Table[0,Length@cs,Length@cs];
Do[is=Position[cs,2i-#][[1,1]]&/@{1,0};
A[[is,is]]+=ds[[i,2]]{{1,-1},{-1,1}},
{i,Length[ds]} ];
MatrixSignature[A]-m ];

GoeritzSignature@Knot[3,1]

GoeritzSignature/@AllKnots[{3,8}]

-KnotSignature/@AllKnots[{3,8}]

Total[(GoeritzSignature[#]==-KnotSignature[#])&/@AllKnots[{3,10}]]

{\red\bf To do.} Tristram-Levine and Alexander in this language.