Pensieve header: Making table1.tex and table2.tex; continuing pensieve://Talks/QMUL-1908/.

SetDirectory["C:\\drorbn\\AcademicPensieve\\Projects\\PG"];
Once[<< KnotTheory`];
Ribbons={Knot[0,1],Knot[6,1],Knot[8,8],Knot[8,9],Knot[8,20],Knot[9,27],Knot[9,41],Knot[9,46],Knot[10,3],Knot[10,22],Knot[10,35],Knot[10,42],Knot[10,48],Knot[10,75],Knot[10,87],Knot[10,99],Knot[10,123],Knot[10,129],Knot[10,137],Knot[10,140],Knot[10,153],Knot[10,155]};

CF=Factor;
(Subscript[𝔼[L_,Q_,P_], $k_]):=𝔼[L,Q,Series[Normal@P,{ϵ,0,$k}]];
(Subscript[(Subscript[𝔼, d_->r_])[L_,Q_,P_], $k_]):=(Subscript[𝔼, d->r])@@(Subscript[𝔼[L,Q,P], $k]);
𝔼3@𝔼[ω_,L_,Q_,Ps_]:=CF/@(Subscript[𝔼[L,(ω^(-1)) Q,(ω^(-1))((((ω^(-4))ϵ))^(-1+Range@Length@Ps)).Ps], $k]);
𝔼4@𝔼[L_,Q_,P_]:=Module[
{ω=((Normal[P])^(-1))/.ϵ->0,Ps=CoefficientList[P,ϵ]},
CF/@𝔼[ω,L,ω Q,(ω^(-3+4Range@Length@Ps))Ps]];
𝔼3@(Subscript[𝔼, sp___])[as___]:=𝔼3@𝔼[as]/.𝔼->(Subscript[𝔼, sp]);
𝔼4@(Subscript[𝔼, sp___])[as___]:=𝔼4@𝔼[as]/.𝔼->(Subscript[𝔼, sp]);

Defining {ω, ρ1, ρ2}.

$k=2;
Clear[QP,ω];
QP[Knot[n_,k_]] := QP[Knot[n,k]]=Collect[Module[{fname},
fname="Data/"<>ToString[n]<>"_"<>ToString[k]<>".m";
Collect[𝔼3[Get[fname][[2,2]]][[3]] // Normal, ϵ, Simplify]
], ϵ, CF];
ω[K_Knot]:=ω[K]=Factor[(((QP@K/.ϵ->0))^(-1))];
(Subscript[c, k_,d_])[K_Knot]:=Factor[SeriesCoefficient[QP[K],{y,0,0}, {ϵ,0,k},{a,0,d}]((ω[K])^(1+2k-d))]

ρ1[K_Knot]:=ρ1[K]=Factor[((T(-(Subscript[c, 1,0])[K]+ω[K]T(∂_T)ω[K]))/(((T-1))^2))];
ρ2[K_Knot]:=ρ2[K]=CF[-2(Subscript[c, 2,0])[K]+ω[K](Subscript[c, 2,1])[K]];
plus[ℰ_]:=Expand[ℰ]/. (T^(n_.))/; n<0 :> 0;

line={ω[#],ρ1[#],ρ2[#]}& /@ {Knot[3,1]}
plus /@ line

ρ2p from ExtractRhos of Roland’s KnotTableWCRho2.nb:

wc11= (1+a+(1/2) (-1-T)-a T+x y) ϵ+((1/2) (a+(a^2)+a T+(a^2) T)+a x y) (ϵ^2)+((O[ϵ])^3);
wc21= (1+a+(1/2) (-1-T)-a T+x y) (ϵ^2)+((O[ϵ])^3);
wc22=((1/4) (1-2 T+(T^2))+a (1-2 T+(T^2))+(a^2) (1-2 T+(T^2))+a (2-2 T) x y+(x^2) (y^2)) (ϵ^2)+((O[ϵ])^3);
ρ2p[Knot[0,1]]=0;
ρ2p[Knot[n_,k_]]:=Module[{Z,Z0,Z1,Z2,Z3,Z4,Alex,rho2},
Z=𝔼3[Get["Data/"<>ToString[n]<>"_"<>ToString[k]<>".m"][[2,2]]];
Z0=Z[[3]];
Alex=(((Normal[Z0]/.ϵ->0))^(-1));
Z1=Z0 *Alex//CF;
Z2=Z1-Coefficient[Z1,y x ϵ]wc11//CF;
Z3=(Z2-Coefficient[Z2,(y^2)(x^2)(ϵ^2)]wc22)//CF;
Z4=Z3-Coefficient[Z3,y x (ϵ^2)]wc21//CF;
rho2=4(((((((-1+T))^2)/T)))^(-1))(Alex^4)(Z4[[3,3]]-(((Z4[[3,2]])^2)/2))//Together//Expand;
Last@Last@CoefficientRules[rho2,(T^(-1))]]

ρ2p[Knot[3,1]]

Column[ρ2p/@AllKnots[{0,6}]]

Recovering Z from {ω, ρ1, ρ2}.

Clear[LogP];
LogP[Knot[n_,k_]] := LogP[Knot[n,k]]=Collect[Module[{fname},
fname="../../Projects/SL2Invariant/k=2/Data/"<>ToString[n]<>"_"<>ToString[k]<>".m";
Collect[ω[Knot[n,k]]*𝔼3[Get[fname][[2,2]]][[3]] //Log// Normal, ϵ, Simplify]
], ϵ, CF];

LogP[Knot[3,1]]

Generating table1.tex and table2.tex

pmrule={"+"->"\\!+\\!", "-"->"\\!-\\!"};
KnotLine[K_] := StringReplace["\\rolcell{n_k}{n^t_{k}}{ω}{ρ1p}{ρ2p}{G}{U}{R}{C}", {
"n" -> ToString@K[[1]],
"k" -> ToString@K[[2]],
"t" -> If[AlternatingQ[K], "a", "n"],
"ω"-> StringReplace[ToString[plus@ω[K], FormatType -> TeXForm],pmrule],
"ρ1p"->  StringReplace[ToString[plus@ρ1[K], FormatType -> TeXForm],pmrule],
"ρ2p"->  StringReplace[ToString[ρ2p[K], FormatType -> TeXForm],pmrule],
"G" -> ToString@ThreeGenus@K,
"U" -> ToString@UnknottingNumber@K,
"R" -> If[MemberQ[Ribbons, K], "\\gY", "\\N"],
"C" -> If[MemberQ[{FullyAmphicheiral, NegativeAmphicheiral, ""}, SymmetryType@K], "\\oY", "\\N"]
}]

KnotLine /@ AllKnots[{0,6}]

Make[range_]:=Make[range,2];
Make[range_,col_] := StringJoin@@Table[
StringJoin[StringJoin@@Riffle[L, " &\n"], " \\\\\n\\hline\n"],
{L, Partition[KnotLine /@ AllKnots[range], UpTo@col]}
];
Make[{0,6},3]

DeleteFile["table1.tex"];
WriteString["table1.tex", Make[{0,8},3]];
Close["table1.tex"]

DeleteFile["table2.tex"];
WriteString["table2.tex", Make[{9,10},2]];
Close["table2.tex"]