Pensieve header: The primary program accompanying “Over then Under Tangles”, by Dror Bar-Natan, Zsuzsanna Dancso, and Roland van der Veen.

This notebook also generates the LATEX file SomeComputations.tex, that corresponds to the section “Some Computations” in the paper.

Mathematica and LATEX Initialization

SetDirectory["C:\\drorbn\\AcademicPensieve\\Projects\\OU"]

{
\def\face{\input{figs/face.pdf_t}}
\def\human{\input{figs/human.pdf_t}}
\def\machine{\input{figs/machine.pdf_t}}

\def\cellscale{1}
\newsavebox\pdfbox
\newlength{\pdfheight}

\def\nbpdfInput#1{{%
  \savebox{\pdfbox}{\includegraphics[scale=\cellscale]{#1}}%
  \settoheight{\pdfheight}{\usebox{\pdfbox}}%
  %\uselengthunit{mm}\printlength{\pdfheight}%
  \noindent\imagetop{\ifdim\pdfheight<10mm\face\else\human\fi}\ %
  \imagetop{\usebox{\pdfbox}}%
  \vskip 2mm%
}}

\def\nbpdfOutput#1{{\noindent{\imagetop{\machine}\ \imagetop{\includegraphics[scale=\cellscale]{#1}}\vskip 2mm}}}

\def\m#1{\text{\tt #1}}

Section Introduction

\subsection{Some Computations} \label{ssec:comp}

We believe in implementing as much as possible. Actually, we hardly believe ourselves unless we implement.

All code here is written in {\sl Mathematica}~\cite{Wolfram:Mathematica} and is available as the {\sl Mathematica} notebook {\sl SomeComputations.nb} at~\cite{Self}.

Virtual Diagrams

\parpic[r]{\input{figs/VDExample.pdf_t}}
To represent a virtual tangle diagram $D$ on the computer, we order its strands and traverse each of them in order, marking each ``O’’ point, each ``U’’ point, and each end of strand with the integers $1,2,3,\ldots$ in the order in which they are encountered. (See examples on the right). For each crossing $x$ of $D$ we form an expression $\m{X}_s[i,j]$, where $s$ is the sign of the crossing and $i$ and $j$ are the markings next to O side and the U side of $x$, respectively. We also for an expression $\m{EOS}[k]$ for each end-of-strand marked $k$. We toss all this information into a container \m{VD}, and the result is our computer representation of $D$. Below, \m{vd1} and \m{vd2} are the results of this process for the two example tangles on the right.

SetAttributes[VD,Orderless]

vd1=VD[(Subscript[X, +1])[1,4],(Subscript[X, +1])[5,2],EOS[3],EOS[6]];
vd2=VD[(Subscript[X, +1])[1,4],(Subscript[X, +1])[2,7],(Subscript[X, +1])[6,3],EOS[5],EOS[8]];

Sometimes in a \m{VD} we allow to label O/U/\m{EOS} points by arbitrary real numbers, for in fact, only the ordering of these points matter. The routine \m{Tidy} takes a real-ordered \m{VD} and converts it to a sequentially ordered one. Thus it brings a \m{VD} to a ``canonical form’’:

Tidy[vd_VD]:=Module[{ps=Union@@(List@@@vd)},
Replace[vd,Thread[ps->Range@Length@ps],{2}] ]

VD[(Subscript[X, +1])[0.9,4.2],(Subscript[X, +1])[5,E],EOS[π],EOS[60]] // Tidy

The routine \m{R12Reduce1} reduces a virtual diagram by performing one R2 or R1 move, if such a move is available, and otherwise it does nothing. The routine \m{R12Reduce} finds the fixed point of \m{R12Reduce1} --- in other words, it reduces a virtual diagram to using all available R1 and R2 moves.

R12Reduce1[vd_VD]:=Tidy@Module[{R2s,R2},Which[
Length[R2s=Cases[vd,(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i+1,j+1]]⋂(List@@vd)]>0,
Complement[vd,VD[R2=First@R2s,R2/.(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i-1,j-1]]],
Length[R2s=Cases[vd,(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i+1,j-1]]⋂(List@@vd)]>0,
Complement[vd,VD[R2=First@R2s,R2/.(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i-1,j+1]]],
True,DeleteCases[vd,(Subscript[X, _])[i_,j_]/;Abs[i-j]==1]  ]];
R12Reduce[vd_VD]:=FixedPoint[R12Reduce1,vd]

Here’s a very minor example:

VD[(Subscript[X, +1])[1,4],(Subscript[X, -1])[2,5],EOS[3],EOS[6]]//R12Reduce

\Needspace{30mm} % 29mm is not enough.
\parpic[r]{
  \def\Xa{$\m{X}_{s_1}[i_1,j_1]$}   \def\Xb{$\m{X}_{s_2}[i_2,j_2]$}
  \def\Xc{$\m{X}_{s_2}[j_1,j_2]$}   \def\Xd{$\m{X}_{s_1}[i_1,i_2]$}
  \def\Xe{$\m{X}_{s_1s_2}[i_1\!-\!s_1/3,j_2\!+\!s_2/3]$}   \def\Xf{$\m{X}_{-s_1s_2}[i_1\!+\!s_1/3,j_2\!-\!s_2/3]$}
  \input{figs/Gamma1.pdf_t}}
In a similar manner, \m{$\Gamma$1} performs one glide move if one is available, and \m{$\barGamma$} fully reduces under both glide moves and R1 and R2 moves. Here we bound the number of iterations by $2^{24}$, to artificially stop runaway reductions such as the one in Figure~\ref{fig:swirls}.

Γ1[vd_VD] :=Module[{js,s1,i1,j1,s2,i2,j2},
js=Cases[vd,(Subscript[X, _])[_,j_]:>j]⋂Cases[vd,(Subscript[X, _])[i_,_]:>i-1];
If[Length[js]==0,vd,
j1=RandomChoice[js]; i2=j1+1;
Cases[vd,(Subscript[X, s_])[i_,j1]:>(s1=s;i1=i)];
Cases[vd,(Subscript[X, s_])[i2,j_]:>(s2=s;j2=j)];
Tidy@Join[Complement[vd,VD[(Subscript[X, s1])[i1,j1],(Subscript[X, s2])[i2,j2]]],
VD[(Subscript[X, s2])[j1,j2],(Subscript[X, s1])[i1,i2],(Subscript[X, s1 s2])[i1-s1/3,j2+s2/3],(Subscript[X, -s1 s2])[i1+s1/3,j2-s2/3]]
]  ]]

Γ[vd_VD]:=FixedPoint[Γ1,vd,(2^24)]

Γ[T_] /; Head[T]=!=VD := Γ[VD[T]]

(OverBar[Γ])[vd_VD]:=FixedPoint[Γ1@*R12Reduce,vd,(2^24)];
(OverBar[Γ])[T_] /; Head[T]=!=VD := (OverBar[Γ])[VD[T]]

As expected, $\barGamma(\m{vd1})=\m{vd2}$:

(OverBar[Γ])[vd1]==vd2

Next we define the composition operation \m{d1**d2} of virtual tangle diagrams. The implementation works by ``shrinking’’ \m{d2} so that each of its strands would fit between the last crossing in the corresponding strand of \m{d1} and the end of that strand, taking the union of \m{d1} and the shrank \m{d2}, and applying \m{Tidy} to the result:

VD /: d1_VD **d2_VD := Tidy@Module[{es1, es2,m2},
es1=Cases[d1,EOS[i_]:>i];
m2=Max[es2=Cases[d2,EOS[i_]:>i]];
d1⋃Replace[DeleteCases[d2,_EOS], i_:>i/m2-1+es1[[1+Count[es2,e_/;i>e]]], {2}]]

For example, ``our’’ \m{vd2} has $3$ crossings yet is equivalent to a 2-twist braid. So $\m{vd1}\cdot\m{vd2}$ ought to have $6$ crossings while it’s reduced OU form, $\barGamma(\m{vd1}\cdot\m{vd2})$ should be the Cinnamon Roll $\CR_4$, which has $7$ crossings. The computer agrees:

{vd2**vd2,(OverBar[Γ])[vd2**vd2]}

Virtual Pure Braids

VPB[n_,{σs___}]:=VPB[n,σs];

vd

vd**vd

vd**vd**vd

VD[VPB[n_]]:=VD@@(EOS/@Range[n]);
VD[VPB[n_,(Subscript[σ, i_,j_])]]:=Tidy@Append[VD@@(EOS/@Range[n]),(Subscript[X, +1])[i-0.5,j-0.5]];
VD[VPB[n_,(Subscript[(OverBar[σ]), i_,j_])]]:=Tidy@Append[VD@@(EOS/@Range[n]),(Subscript[X, -1])[i-0.5,j-0.5]];
VD[VPB[n_,σ_,σs__]]:=VD[VPB[n,σ]]**VD[VPB[n,σs]]

VD[VPB[5,(Subscript[(OverBar[σ]), 4,2])]]

vd1=VD[VPB[5,(Subscript[σ, 2,3])]]

vd2=VD[VPB[5,(Subscript[σ, 3,4])]]

VD[VPB[5,(Subscript[σ, 2,3]),(Subscript[σ, 3,4])]]

VD[VPB[5,(Subscript[σ, 2,3]),(Subscript[σ, 3,4])]]//Γ

VPB[3,(Subscript[σ, 1,2]),(Subscript[σ, 1,3]),(Subscript[σ, 2,3])]// Γ

VPB[3,(Subscript[σ, 2,3]),(Subscript[σ, 1,3]),(Subscript[σ, 1,2])]// Γ

R2ReduceB[vd_VD]:=Module[{R2s,R2},
R2s=Cases[vd,(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i+1,j+1]]⋂(List@@vd);
If[Length[R2s]==0,vd,
R2=First@R2s;
Tidy@Complement[vd,VD[R2,R2/.(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i-1,j-1]]]
]]

R2ReduceC[vd_VD]:=Module[{R2s,R2},
R2s=Cases[vd,(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i+1,j-1]]⋂(List@@vd);
If[Length[R2s]==0,vd,
R2=First@R2s;
Tidy@Complement[vd,VD[R2,R2/.(Subscript[X, s_])[i_,j_]:>(Subscript[X, -s])[i-1,j+1]]]
]]

R2Reduce[vd_VD]:=FixedPoint[R2ReduceB @* R2ReduceC,vd]

R1Reduce1[vd_VD]:=Tidy@DeleteCases[vd,(Subscript[X, _])[i_,j_]/;Abs[i-j]==1]

VPB[3,(Subscript[σ, 1,2]),(Subscript[σ, 1,3]),(Subscript[σ, 2,3])]// Γ//R2Reduce

VPB[2,(Subscript[σ, 1,2]),(Subscript[σ, 2,1])]//VD

VPB[2,(Subscript[σ, 1,2]),(Subscript[σ, 2,1])]//VD//Γ

VPB[2,(Subscript[σ, 1,2]),(Subscript[σ, 2,1])]//VD//Γ//R2Reduce

VPB[2,(Subscript[σ, 1,2]),(Subscript[σ, 2,1])]//VD//Γ//R12Reduce

Test1[n_,m_]:=Module[{gens,i,j,k,l},
gens=Flatten@Table[{(Subscript[σ, i,j]),(Subscript[(OverBar[σ]), i,j])},{i,n},{j,DeleteCases[Range@n,i]}];
Table[
{i,j,k}=ijk;
(OverBar[Γ])[VPB[n,Sequence@@p,(Subscript[σ, i,j]),(Subscript[σ, i,k]),(Subscript[σ, j,k]),Sequence@@q]]==(OverBar[Γ])[VPB[n,Sequence@@p,(Subscript[σ, j,k]),(Subscript[σ, i,k]),(Subscript[σ, i,j]),Sequence@@q]],
{l,0,m-3},{p,Tuples[gens,l]},{q,Tuples[gens,m-3-l]},
{ijk,Join@@(Permutations/@Subsets[Range[n],{3}])}
]]

Test1[3,3]

Timing@Union@Flatten@Test1[4,5]

Timing@Union@Flatten@Test1[5,4]

Test2[n_,m_]:=Module[{gens,s,r=0,ij,ijk,ijkl,perm,i,j,k,l,tests},
gens=Flatten@Table[{(Subscript[σ, i,j]),(Subscript[(OverBar[σ]), i,j])},{i,n},{j,DeleteCases[Range@n,i]}];
tests=Flatten[{
Table[{i,j}=ij; {
T[VPB[n,Join[p,{(Subscript[σ, i,j]),(Subscript[(OverBar[σ]), i,j])},q]],VPB[n,Join[p,q]]],
T[VPB[n,Join[p,{(Subscript[(OverBar[σ]), i,j]),(Subscript[σ, i,j])},q]],VPB[n,Join[p,q]]]
},
{s,0,m-2},{t,0,s},{p,Tuples[gens,t]},{q,Tuples[gens,s-t]},
{ij,Join@@(Permutations/@Subsets[Range[n],{2}])}
],
Table[{i,j,k}=ijk; {
T[VPB[n,Join[p,{(Subscript[σ, i,j]),(Subscript[σ, i,k]),(Subscript[σ, j,k])},q]],VPB[n,Join[p,{(Subscript[σ, j,k]),(Subscript[σ, i,k]),(Subscript[σ, i,j])},q]]],
T[VPB[n,Join[p,{(Subscript[(OverBar[σ]), j,i]),(Subscript[σ, i,k]),(Subscript[σ, j,k])},q]],VPB[n,Join[p,{(Subscript[σ, j,k]),(Subscript[σ, i,k]),(Subscript[(OverBar[σ]), j,i])},q]]],
T[VPB[n,Join[p,{(Subscript[σ, i,j]),(Subscript[σ, i,k]),(Subscript[(OverBar[σ]), k,j])},q]],VPB[n,Join[p,{(Subscript[(OverBar[σ]), k,j]),(Subscript[σ, i,k]),(Subscript[σ, i,j])},q]]],
T[VPB[n,Join[p,{(Subscript[σ, i,j]),(Subscript[(OverBar[σ]), k,i]),(Subscript[(OverBar[σ]), k,j])},q]],VPB[n,Join[p,{(Subscript[(OverBar[σ]), k,j]),(Subscript[(OverBar[σ]), k,i]),(Subscript[σ, i,j])},q]]],
T[VPB[n,Join[p,{(Subscript[(OverBar[σ]), j,i]),(Subscript[(OverBar[σ]), k,i]),(Subscript[σ, j,k])},q]],VPB[n,Join[p,{(Subscript[σ, j,k]),(Subscript[(OverBar[σ]), k,i]),(Subscript[(OverBar[σ]), j,i])},q]]],
T[VPB[n,Join[p,{(Subscript[(OverBar[σ]), j,i]),(Subscript[(OverBar[σ]), k,i]),(Subscript[(OverBar[σ]), k,j])},q]],VPB[n,Join[p,{(Subscript[(OverBar[σ]), k,j]),(Subscript[(OverBar[σ]), k,i]),(Subscript[(OverBar[σ]), j,i])},q]]]
},
{s,0,m-3},{t,0,s},{p,Tuples[gens,t]},{q,Tuples[gens,s-t]},
{ijk,Join@@(Permutations/@Subsets[Range[n],{3}])}
],
Table[{i,j,k,l}=ijkl[[perm]]; {
T[VPB[n,Join[p,{(Subscript[σ, i,j]),(Subscript[σ, k,l])},q]],VPB[n,Join[p,{(Subscript[σ, k,l]),(Subscript[σ, i,j])},q]]],
T[VPB[n,Join[p,{(Subscript[(OverBar[σ]), i,j]),(Subscript[σ, k,l])},q]],VPB[n,Join[p,{(Subscript[σ, k,l]),(Subscript[(OverBar[σ]), i,j])},q]]],
T[VPB[n,Join[p,{(Subscript[σ, i,j]),(Subscript[(OverBar[σ]), k,l])},q]],VPB[n,Join[p,{(Subscript[(OverBar[σ]), k,l]),(Subscript[σ, i,j])},q]]],
T[VPB[n,Join[p,{(Subscript[(OverBar[σ]), i,j]),(Subscript[(OverBar[σ]), k,l])},q]],VPB[n,Join[p,{(Subscript[(OverBar[σ]), k,l]),(Subscript[(OverBar[σ]), i,j])},q]]]
},
{s,0,m-2},{t,0,s},{p,Tuples[gens,t]},{q,Tuples[gens,s-t]},
{ijkl,Subsets[Range[n],{4}]},{perm,{{1,2,3,4},{1,3,2,4},{1,4,2,3}}}
]
}];
Cases[tests, T[b1_,b2_]/;(OverBar[Γ])[b1]=!=(OverBar[Γ])[b2]]
]

Timing@Test2[3,3]

Timing@Test2[3,4]

Timing@Test2[3,5]

Timing@Test2[4,2]

Timing@Test2[4,3]

VPB[3,(Subscript[(OverBar[σ]), 1,2]),(Subscript[σ, 1,3]),(Subscript[σ, 2,3])]//Γ//R2Reduce

VPB[3,(Subscript[σ, 2,3]),(Subscript[σ, 1,3]),(Subscript[(OverBar[σ]), 1,2])]//Γ//R2Reduce

AllVPBInvariants[n_,m_]:=Module[{gens,k},
gens=Flatten@Table[{(Subscript[σ, i,j]),(Subscript[(OverBar[σ]), i,j])},{i,n},{j,DeleteCases[Range@n,i]}];
Flatten@Table[VPB[n,Sequence@@p]->(OverBar[Γ])@VPB[n,Sequence@@p], {k,0,m},{p,Tuples[gens,k]}]]

AllVPBInvariants[2,2]//Column

VPBGenerators[n_]:=VPBGenerators[n]=Flatten@Table[{(Subscript[σ, i,j]),(Subscript[(OverBar[σ]), i,j])},{i,n},{j,DeleteCases[Range@n,i]}];

VPBGenerators[5]

(*CountOUForms[n_,m_]:=Module[{k},
Length@Union@Flatten@Table[R12Reduce@Γ@VPB[n,Sequence@@p], {k,0,m},{p,Tuples[VPBGenerators[n],k]}]]*)

ProudFollowers[n_,(Subscript[σ, i_,j_])] :=ProudFollowers[n,(Subscript[σ, i,j])]=Module[{p,q,s},
Flatten@{(Subscript[σ, i,j]),(Subscript[σ, j,i]),(Subscript[(OverBar[σ]), j,i]),
Table[{(Subscript[σ, p,q]),(Subscript[σ, q,p]),(Subscript[(OverBar[σ]), p,q]),(Subscript[(OverBar[σ]), q,p])},{p,{i,j}},{q,Complement[Range[n],{i,j}]}],
Table[{(Subscript[σ, p,q]),(Subscript[(OverBar[σ]), p,q])},{p,Complement[Range[i+1,n],{j}]},{q,Complement[Range[n],{i,j,p}]}]
}];
ProudFollowers[n_,(Subscript[(OverBar[σ]), i_,j_])] := ProudFollowers[n,(Subscript[(OverBar[σ]), i,j])]=ProudFollowers[n,(Subscript[σ, i,j])]/.(Subscript[σ, i,j])->(Subscript[(OverBar[σ]), i,j])

ProudFollowers[5,(Subscript[σ, 2,3])]

ProudFollowers[5,(Subscript[(OverBar[σ]), 2,3])]

ProudVPBs[n_,0]:={VPB[n]};
ProudVPBs[n_,1]:=VPB[n,#]&/@VPBGenerators[n];
ProudVPBs[n_,m_]/;m>1:=Flatten[ProudVPBs[n,m-1]/.VPB[n,σs___,σ_]:>(VPB[n,σs,σ,#]&/@ProudFollowers[n,σ])]

ProudVPBs[2,2]

ProudVPBs[3,3]

CountOUForms[n_,m_]:=Module[{k},
Length@Union@Flatten@Table[(OverBar[Γ])@vpb, {k,0,m},{vpb,ProudVPBs[n,k]}]]

Timing@CountOUForms[2,1]

Timing@CountOUForms[2,2]

Timing@CountOUForms[2,3]

Timing@CountOUForms[2,4]

Timing@CountOUForms[2,5]

Timing@CountOUForms[2,6]

FindSequenceFunction[{5,17,53,161,485,1457}]

FindLinearRecurrence[{5,17,53,161,485,1457}]

Timing@CountOUForms[3,1]

Timing@CountOUForms[3,2]

Timing@CountOUForms[3,3]

Timing@CountOUForms[3,4]

Timing@CountOUForms[3,5]

Timing@CountOUForms[3,6]

((17038.5`)^2)/484.328125`

FindSequenceFunction[{13,145,1561,16717,178873,1913737}]

Timing@CountOUForms[4,1]

Timing@CountOUForms[4,2]

Timing@CountOUForms[4,3]

Timing@CountOUForms[4,4]

Timing@CountOUForms[4,5]

((9002.375`)^2)/243.4375`

{25,529,10873,222289,4540201}

Timing@CountOUForms[5,1]

Timing@CountOUForms[5,2]

Timing@CountOUForms[5,3]

Timing@CountOUForms[5,4]

((1459.640625`)^2)/24.515625`

{41,1361,43121, 1351481}

Timing@CountOUForms[6,1]

Timing@CountOUForms[6,2]

Timing@CountOUForms[6,3]

Timing@CountOUForms[6,4]

FindSequenceFunction@{61,2881,127021,5484721}

Timing@CountOUForms[7,1]

Timing@CountOUForms[7,2]

Timing@CountOUForms[7,3]

{85,5377,310633}

Timing@CountOUForms[8,1]

Timing@CountOUForms[8,2]

Timing@CountOUForms[8,3]

{113,9185,668081}

Timing@CountOUForms[9,1]

Timing@CountOUForms[9,2]

Timing@CountOUForms[9,3]

CountOUForms[n,1]:

n//FindSequenceFunction@{1,5,13,25,41,61,85,113,145}//Simplify//TeXForm

CountOUForms[n,2]:

n//FindSequenceFunction@{1,17,145,529,1361,2881,5377,9185,14689}//Simplify//TeXForm

CountOUForms[n,3]:

n//FindSequenceFunction@{1,53,1561,10873,43121,127021,310633,668081,1307233}//Simplify//TeXForm

n//FindSequenceFunction@{1,53,1561,10873,43121,127021,310633,668081,1307233}

(1/3) (3-558 n+1066 (n^2)-546 (n^3)-2 (n^4)+36 (n^5)+4 (n^6)) /. n->1

LATEX Epilogue

Should eventually be incorporated above and emptied.

{\red MORE\hfill Tabulate the results! \hfill MORE}

\vskip 5mm
\Needspace{90mm}
$n$-strand classical braids with $(\leq m)$-xing:

{\def\u#1{\underline{#1}}
\setlength{\tabcolsep}{3pt}
\small\begin{tabular}{|c|c|c|c|c|c|l|}
\hline
$m\backslash n$ &       2 &     3 &             4 &             5 &             6 &             General $n$ \\
\hline
0               &       1 &     1 &             1 &             1 &             1 &             $1$ \\
1               &       3 &     5 &             7 &             9 &             11 &            {\tiny$2n-1$} \\
2               &       5 &     17 &            33 &            53 &            77 &            {\tiny$2n^2+2n-7$} \\
3               &       7 &     47 &            131 &           259 &           439 &           {\tiny$\frac{1}{3} \left(4n^3+18n^2-22n-63\right)\ (n>2)$} \\
4               &       9 &     115 &           469 &           1143 &          2233 &          \\
5               &       11 &    263 &           1579 &          4743 &          10603 &         \\
6               &       13 &    577 &           5121 &          18941 &         48209 &         \\
7               &       15 &    1233 &          16219 &         73817 &         213119 &        \\
8               &       17 &    2589 &          50581 &         283165 &        924865 &        \\
9               &       19 &    5371 &          156127 &        1074963 &       3964411 &       \\
$m$             &       {\tiny$2m+1$} & {\tiny$12\cdot 2^m - 2F_{m+5} - 2m - 1$\ ?}& & & &      \\
\hline
\end{tabular}}

\vskip 5mm
\Needspace{50mm}
$n$-strand (pure) virtual braids with $(\leq m)$-xing:

{\def\u#1{\underline{#1}}
\setlength{\tabcolsep}{3pt}
\small\begin{tabular}{|c|c|c|c|c|c|l|}
\hline
$m\backslash n$ &       2 &             3 &                     4 &                     5 &                     6 &                     General $n$ \\
\hline
0               &       \u{1} &         \u{1} &                 \u{1} &                 \u{1} &                 \u{1} &                 $1$ \\
1               &       \u{5} &         \u{13} &                \u{25} &                \u{41} &                \u{61} &                {\tiny$2 n^2-2 n+1$} \\
2               &       \u{17} &        \u{145} &               \u{529} &               \u{1361} &              \u{2881} &              {\tiny$2 n^4+4 n^3-18 n^2+12 n+1$} \\
3               &       \u{53} &        \u{1561} &              \u{10873} &             \u{43121} &             \u{127021} &            {\tiny$\frac{1}{3} \left(4 n^6+36 n^5-2 n^4-546 n^3+1066 n^2-558 n+3\right)$} \\
4               &       \u{161} &       \u{16717} &             \u{222289} &            1351481 &               5484721 &               \\
5               &       \u{485} &       \u{178873} &            4540201 &               &                       &                       \\
6               &       \u{1457} &      1913737 &               &                       &                       &                       \\
$m$             &       {\tiny$2\cdot 3^m-1$} & &               &                       &                       &                       \\
\hline
\end{tabular}}

}