C in the middle, (Subscript[t, i ])becomes t. And a =  (ue^(-ϵ c)). And finally η = -ϵ ((1+t)/(1-t))

ϵ /: (ϵ^(n_))/;n>1 :=0;
PBWBasis={a,c,w};

B[U@c,U@u]=-(B[U@u,U@c]=-U@u);
B[U@u,U@w]=-(B[U@w,U@u]=(1-t)U[]+ϵ  U[u,w]-2ϵ t  U[c]);

B[U@c,U@w]=-(B[U@w,U@c]=U@w);
B[U@c,U@a]=-(B[U@a,U@c]=-U@a);
B[U@a,U@w]=-(B[U@w,U@a]=(1-t)U[]-ϵ(1+t) U[c]);
(*
B[U@a,U@w]=-(B[U@w,U@a]= (1-t)U[]+η(1-t) U[c]);   
*)

(*Setting a = (ue^(-ϵc)) gives the bracket as above*)
U@w**U@u**(U[]-ϵ U[c])-U@u**(U[]-ϵ U[c])**U[w]-((1-t)U[]-ϵ (1+t ) U[c] )//Simp

UU[l___,((x_)^(n_)),r___]:= UU[l,Sequence@@Table[x,{n}],r];
UU[l___,1,r___]:= UU[l,r];
UU[]=U[]; UU[l_,r___]:=U[l]**UU[r];
(Subscript[U, i_])[ℰ_] := ℰ /. {t->(Subscript[t, i]), u_U :> UU@@Replace[u, x_ :> (Subscript[x, i]),1]};

B[x_,x_]=0;
B[U[(Subscript[(x_), i_])],U[(Subscript[(y_), i_])]]:=(Subscript[U, i])[B[U@x,U@y]];
B[U[(Subscript[(x_), i_])],U[(Subscript[(y_), j_])]] /; i=!=j := 0;
B[x_,y_] := x**y-y**x;

x_⪯y_:=OrderedQ[{x,y}]; x_≺y_:=!OrderedQ[{y,x}];
Simp[ℰ_]:= Collect[ℰ, _U,Together];

Unprotect[NonCommutativeMultiply];
NonCommutativeMultiply[x_] := x;
0**_=_**0=0;
x_**U[]:=x; U[]**x_:=x;
(a_*x_U)**(b_*y_U) := If[a b === 0, 0, Simp[a b (x**y)]];
(a_*x_U)**y_ := Simp[a(x**y)]; x_**(a_*y_U) := Simp[a(x**y)];
(x_Plus)**y_ := (#**y)& /@ x; x_**(y_Plus) := (x**#)& /@ y;
U[x_]**U[y_] := (*U[x]**U[y] =*) If[x≺y, U[x,y], U[y,x]+B[U@x,U@y]];
U[x_] ** U[y1_,yy__] := (*U[x] ** U[y1,yy] =*)If[x⪯y1,U[x,y1,yy],(U@x**U@y1)**U@yy];
U[xx__,xn_]**U[yy__] := (*U[xx,xn]**U[yy] =*) U@xx**(U@xn**U@yy);

σ[i_,j_][ℰ_] := ℰ /. {(Subscript[b, i])->(Subscript[b, j]),(Subscript[t, i])->(Subscript[t, j]),(Subscript[a, i])->(Subscript[a, j]),(Subscript[c, i])->(Subscript[c, j]),(Subscript[u, i])->(Subscript[u, j]),(Subscript[w, i])->(Subscript[w, j])};

mul[i_,j_][ℰ_] := Simp[ℰ /. x_U :> DeleteCases[x,(Subscript[_, j])]**U@@Cases[x,(Subscript[y_, j]):>(Subscript[y, i])] /. {(Subscript[b, j])->(Subscript[b, i]), (Subscript[t, j])->(Subscript[t, i])}];
mul[i_,j_,k_][ℰ_] := ℰ // mul[i,j] // σ[i,k];

Δ[i_,j_,k_][ℰ_] := Simp[ℰ/. {
z_.U[]:>(z /. {(Subscript[b, i])->(Subscript[b, j])+(Subscript[b, k]),(Subscript[t, i])->(Subscript[t, j])(Subscript[t, k])})U[],
z_.x_U :> (z /. {(Subscript[b, i])->(Subscript[b, j])+(Subscript[b, k]),(Subscript[t, i])->(Subscript[t, j])(Subscript[t, k])})NonCommutativeMultiply@@(x /. {
(Subscript[c, i])->U@(Subscript[c, j])+U@(Subscript[c, k]),
 (Subscript[u, i])->(Subscript[t, k]) U@(Subscript[u, j])+ϵ (Subscript[t, k]) UU[(Subscript[c, k]),(Subscript[u, j])]+U@(Subscript[u, k]),
 (Subscript[w, i])->U@(Subscript[w, j])+ϵ UU[(Subscript[c, k]),(Subscript[w, j])]+U@(Subscript[w, k]),
(Subscript[a, i])->(Subscript[t, k]) U[(Subscript[a, j])]+U[(Subscript[a, k])]-ϵ U[(Subscript[a, k]),(Subscript[c, j])],
 (Subscript[y_, l_]):>U@(Subscript[y, l])
})
}]

S[i_][ℰ_] := Simp[ℰ /. {z_.x_U:>(z /. {(Subscript[b, i])->-(Subscript[b, i]),(Subscript[t, i])->((Subscript[t, i])^(-1))})S[i][x]}];
S[i_][U[]]=U[];
S[i_][U[(Subscript[y_, j_]),more___]] /; i≠j := U[(Subscript[y, j])]**S[i][U[more]];   (*Careful! if mathematica cannot decide i==j or not then we get an error*)
S[i_][U[(Subscript[c, i_]),more___]] := S[i][U[more]]**(-U@(Subscript[c, i]));
S[i_][U[(Subscript[u, i_]),more___]] := S[i][U[more]]**(-((Subscript[t, i])^(-1))U@(Subscript[u, i])+Expand[ϵ ((Subscript[t, i])^(-1))UU[(Subscript[u, i]),(Subscript[c, i])]]);
S[i_][U[(Subscript[w, i_]),more___]] := S[i][U[more]]**(-U@(Subscript[w, i])+Expand[ϵ UU[(Subscript[w, i]),(Subscript[c, i])]]);S[i_][U[(Subscript[a, i_]),more___]] := S[i][U[more]]**(Expand[-((Subscript[t, i])^(-1))((1+ϵ) U[(Subscript[a, i])]+ϵ U[(Subscript[a, i]),(Subscript[c, i])])]);

Sinv[i_][ℰ_] := Simp[ℰ /. {z_.x_U:>(z /. {(Subscript[b, i])->-(Subscript[b, i]),(Subscript[t, i])->((Subscript[t, i])^(-1))})Sinv[i][x]}];
Sinv[i_][U[]]=U[];
Sinv[i_][U[(Subscript[y_, j_]),more___]] /; i≠j := U[(Subscript[y, j])]**Sinv[i][U[more]];   (*Careful! if mathematica cannot decide i==j or not then we get an error*)
Sinv[i_][U[(Subscript[c, i_]),more___]] := Sinv[i][U[more]]**(-U@(Subscript[c, i]));
Sinv[i_][U[(Subscript[u, i_]),more___]] := Sinv[i][U[more]]**(-((Subscript[t, i])^(-1))U@(Subscript[u, i])+Expand[ϵ ((Subscript[t, i])^(-1))UU[(Subscript[c, i]),(Subscript[u, i])]]);
Sinv[i_][U[(Subscript[w, i_]),more___]] := Sinv[i][U[more]]**(-U@(Subscript[w, i])+Expand[ϵ UU[(Subscript[c, i]),(Subscript[w, i])]]);Sinv[i_][U[(Subscript[a, i_]),more___]] := Sinv[i][U[more]]**(Expand[-((Subscript[t, i])^(-1))( U[(Subscript[a, i])]+ϵ U[(Subscript[a, i]),(Subscript[c, i])])]);

CoUnit[i_][ℰ_] :=Simp[ℰ/. {z_.x_U:>(z/. {t->1,b->0,(Subscript[b, i])->0,(Subscript[t, i])->1})CoUnit[i][x]}] ;
CoUnit[i_][U[]]=U[];
CoUnit[i_][U[(Subscript[y_, j_]),more___]] /; i≠j := U[(Subscript[y, j])]**CoUnit[i][U[more]];
CoUnit[i_][U[(Subscript[y_, i_]),more___]] /;y≠a:=0;
CoUnit[i_][U[(Subscript[a, i_]),more___]]:= CoUnit[i][U[more]];

LBasis[n_Integer] := LBasis[Range[n]];
LBasis[S_] := DeleteCases[0]@Module[{i,j,k,l}, SortBy[(# /. {ϵ->2,(Subscript[c, _])->2,(Subscript[u, _])->2,(Subscript[w, _])->2, U->Times})&][
Union@Flatten[{{U[],ϵ U[]},
Table[{U@(Subscript[c, i]),U@(Subscript[u, i]),U@(Subscript[w, i]),ϵ U@(Subscript[c, i]),ϵ U@(Subscript[u, i]),ϵ U@(Subscript[w, i])}, {i,S}],
Table[{U[(Subscript[u, i]),(Subscript[w, j])],ϵ U[(Subscript[u, i]),(Subscript[w, j])],ϵ U@@Sort@{(Subscript[c, i]),(Subscript[c, j])},ϵ U[(Subscript[c, i]),(Subscript[u, j])],ϵ U[(Subscript[c, i]),(Subscript[w, j])]}, {i,S}, {j,S}],
Table[{ϵ U[(Subscript[c, i]),(Subscript[u, j]),(Subscript[w, k])],ϵ U@@Sort@{(Subscript[u, i]),(Subscript[u, j]),(Subscript[w, k])},ϵ U@@Sort@{(Subscript[u, i]),(Subscript[w, j]),(Subscript[w, k])}}, {i,S}, {j,S},{k,S}],
Table[ϵ U@@Sort@{(Subscript[u, i]),(Subscript[u, j]),(Subscript[w, k]),(Subscript[w, l])}, {i,S}, {j,S},{k,S},{l,S}] }]
]]

BLBasis[n_Integer] := BLBasis[Range[n]];
BLBasis[S_] := DeleteCases[0]@Module[{i,j,k,l}, SortBy[(# /. {ϵ->2,(Subscript[c, _])->2,(Subscript[u, _])->2,(Subscript[w, _])->2, U->Times})&][
Union@Flatten[{{U[],ϵ U[]},
Table[{U@(Subscript[c, i]),ϵ U@(Subscript[c, i])}, {i,S}],
Table[{U[(Subscript[u, i]),(Subscript[w, j])],ϵ U[(Subscript[u, i]),(Subscript[w, j])],ϵ U@@Sort@{(Subscript[c, i]),(Subscript[c, j])}}, {i,S}, {j,S}],
Table[{ϵ U[(Subscript[c, i]),(Subscript[u, j]),(Subscript[w, k])]}, {i,S}, {j,S},{k,S}],
Table[ϵ U@@Sort@{(Subscript[u, i]),(Subscript[u, j]),(Subscript[w, k]),(Subscript[w, l])}, {i,S}, {j,S},{k,S},{l,S}] }]
]]

UExp[ℰ_,n_]:=Module[{t=U[],k}, U[]+Sum[((t=t**ℰ)/(k!)), {k,n}]]//Simp

ToDegree[n_][ℰ_] := (Simp[ℰ] /. {ϵ->ℏ ϵ,η->ℏ η, (Subscript[b, i_]):>ℏ (Subscript[b, i]), (Subscript[t, i_]):>(E^(ℏ (Subscript[b, i]))),b->ℏ b,  t:>(E^(ℏ b)),x_U:>(ℏ^(Count[x,u|(Subscript[u, _])]+Count[x,a|(Subscript[a, _])]))x} /. a_.x_U :>Normal[Series[a,{ℏ,0,n}]]*x)/.ℏ->1

Hopf algebra axioms

(*Sinv is the inverse of S *)
Sinv[1][S[1][U@(Subscript[a, 1])]]//Simp
Sinv[1][S[1][U@(Subscript[c, 1])]]//Simp
Sinv[1][S[1][U@(Subscript[w, 1])]]//Simp
Sinv[1][S[1][U@(Subscript[u, 1])]]//Simp

(*Coassociativity only works properly with (Subscript[t, i]) instead of t!*)
(U@(Subscript[w, 1])//Δ[1,x,yy]//Δ[yy,y,z])-
(U@(Subscript[w, 1])//Δ[1,xx,z]//Δ[xx,x,y])
(U@(Subscript[c, 1])//Δ[1,x,yy]//Δ[yy,y,z])-
(U@(Subscript[c, 1])//Δ[1,xx,z]//Δ[xx,x,y])
(U@(Subscript[a, 1])//Δ[1,x,yy]//Δ[yy,y,z])-
(U@(Subscript[a, 1])//Δ[1,xx,z]//Δ[xx,x,y])//Simp
(U@(Subscript[u, 1])//Δ[1,x,yy]//Δ[yy,y,z]//Simp)-
(U@(Subscript[u, 1])//Δ[1,xx,z]//Δ[xx,x,y]//Simp)//Simp

(*Convolution inverse*)
mul[2,3,1][S[2][Δ[1,2,3][U[(Subscript[w, 1])]]]]
mul[2,3,1][S[2][Δ[1,2,3][U[(Subscript[c, 1])]]]]
mul[2,3,1][S[2][Δ[1,2,3][U[(Subscript[u, 1])]]]]
mul[2,3,1][S[2][Δ[1,2,3][U[(Subscript[a, 1])]]]]

mul[2,3,1][S[3][Δ[1,2,3][U[(Subscript[w, 1])]]]]
mul[2,3,1][S[3][Δ[1,2,3][U[(Subscript[c, 1])]]]]
mul[2,3,1][S[3][Δ[1,2,3][U[(Subscript[u, 1])]]]]
mul[2,3,1][S[3][Δ[1,2,3][U[(Subscript[a, 1])]]]]

Testing Yang-Baxter

R[i_,j_,d_]:= Sum[((UU[((Subscript[a, i])^n)]**(U[]+ϵ n U[(Subscript[c, i])])**(((Subscript[b, i])^m)U[]+ϵ m ((Subscript[b, i])^(m-1))U[(Subscript[c, i])])**UU[((Subscript[c, j])^m),((Subscript[w, j])^n)])/(m!n!))(1+ϵ(1/4)(n-1)n),{m,0,d},{n,0,d-m}]//ToDegree[d]

RU[i_,j_,d_]:= Sum[((UU[((Subscript[u, i])^n)]**(((Subscript[b, i])^m)U[]+ϵ m ((Subscript[b, i])^(m-1))U[(Subscript[c, i])])**UU[((Subscript[c, j])^m),((Subscript[w, j])^n)])/(m!n!))(1-(ϵ/4)(n-1)n),{m,0,d},{n,0,d-m}]//ToDegree[d]

RU3[d_] := (ToDegree[d][RU[1,2,d]**RU[1,3,d]]**RU[2,3,d])-(ToDegree[d][RU[2,3,d]**RU[1,3,d]]**RU[1,2,d])

Timing[RU3[2] // ToDegree[2]]

Timing[RU3[3] // ToDegree[3]]

Timing[RU3[4] // ToDegree[4]]

R3[d_] := (ToDegree[d][R[1,2,d]**R[1,3,d]]**R[2,3,d])-(ToDegree[d][R[2,3,d]**R[1,3,d]]**R[1,2,d])

R3[2] // ToDegree[2]

Timing[R3[3] // ToDegree[3]]

Timing[R3[4] // ToDegree[4]]

(*Verifying the inverse is given by (S tensor id)(R)*)
(S[1][R[1,2,4]]**R[1,2,4]-U[])//ToDegree[4]
(*Verifying the inverse is given by (id tensor S^{-1})(R)  *)

(Sinv[2][R[1,2,4]]**R[1,2,4]-U[])//ToDegree[4]

Rinv[i_,j_,d_]:=S[i][R[i,j,d]]//Expand

(*Alternative formulas for Rinv, Rinv4 is the definitive one*)

TestS[m_,n_]:=-S[i][UU[((Subscript[a, i])^n)]**(U[]+ϵ n U[(Subscript[c, i])])**(((Subscript[b, i])^m)U[]+ϵ m ((Subscript[b, i])^(m-1))U[(Subscript[c, i])])]+
(((-1))^m)(((Subscript[b, i])^m)U[]+ϵ m ((Subscript[b, i])^(m-1))U[(Subscript[c, i])])**(U[]-ϵ n U[(Subscript[c, i])])**San[n,i]
TestS[4,3]//Together
0
San[n_,i_]:=(((-1))^n)((Subscript[t, i])^(-n))UU[((Subscript[a, i])^n)]**(U[]+((n(n+1))/2)ϵ U[]+n ϵ U[(Subscript[c, i])])//Expand
TestSan[n_]:=-S[i][UU[((Subscript[a, i])^n)]]+San[n,i]
(TestSan[6]//Together)
0
Rinv2[i_,j_,d_]:= Sum[(((((-1))^m)(((Subscript[b, i])^m)U[]+ϵ m ((Subscript[b, i])^(m-1))U[(Subscript[c, i])])**(U[]-ϵ n U[(Subscript[c, i])])**San[n,i]**UU[((Subscript[c, j])^m),((Subscript[w, j])^n)])/(m!n!))(1+ϵ(1/4)(n-1)n),{m,0,d},{n,0,d-m}]//ToDegree[d]

Rinv3[i_,j_,d_]:= Sum[(((((-1))^m)San[n,i]**(((Subscript[b, i])^m)U[]+ϵ m ((Subscript[b, i])^(m-1))U[(Subscript[c, i])]+ϵ m n ((Subscript[b, i])^(m-1))U[])**(U[]-ϵ n U[(Subscript[c, i])]-ϵ (n^2)U[])**UU[((Subscript[c, j])^m),((Subscript[w, j])^n)])/(m!n!))(1+ϵ(1/4)(n-1)n),{m,0,d},{n,0,d-m}]//ToDegree[d]

Rinv4[i_,j_,d_]:= Sum[(((((-1))^(m+n))((Subscript[t, i])^(-n))UU[((Subscript[a, i])^n)]**(((Subscript[b, i])^m)U[]+ϵ m ((Subscript[b, i])^(m-1))U[(Subscript[c, i])]+ϵ m n ((Subscript[b, i])^(m-1))U[])**UU[((Subscript[c, j])^m),((Subscript[w, j])^n)])/(m!n!))(1-ϵ(1/4)(n-1)n),{m,0,d},{n,0,d-m}]//ToDegree[d]

(Rinv[1,2,6]-Rinv2[1,2,6])//Simp//ToDegree[6]
Rinv[1,2,6]-Rinv3[1,2,6]//ToDegree[6]
Rinv[1,2,6]-Rinv4[1,2,6]//ToDegree[6]

Quasi triangularity axioms

(*Check the three quasi-triangularity axioms*)

(Δ[i,k,l][R[i,j,5]]-R[k,j,5]**R[l,j,5])//ToDegree[5]

(Δ[j,k,l][R[i,j,5]]-R[i,l,5]**R[i,k,5])//ToDegree[5]

CheckRDR[x_,d_]:=(R[2,3,d]**Δ[1,2,3][x]**Rinv[2,3,d]-σ[2,3][Δ[1,2,3][x]])//ToDegree[d]

CheckRDR[U@(Subscript[c, i]),4]
CheckRDR[U@(Subscript[w, i]),4]
CheckRDR[U@(Subscript[a, i]),4]

Drinfeld element

(*Drinfeld element*)
Dr[d_]:= R[1,2,d]//S[2]//mul[2,1,1]

(*Check that S(Dr) and Dr commute*)
S[1][Dr[4]]**Dr[4]-S[1][Dr[4]]**Dr[4]

S[1][Dr[2]]//ToDegree[2]

(*S(Dr) = (t^(-1 ))(e^(-2ϵc)) Dr *)
S[1][Dr[5]]-(U[]-2ϵ U[(Subscript[c, 1])])**(Dr[5]((Subscript[t, 1])^(-1))//ToDegree[5])//ToDegree[5]

(U[]-ϵ U[(Subscript[c, 1])])**Dr[4]-Dr[4]**(U[]-ϵ U[(Subscript[c, 1])])//ToDegree[4]

Therefore the Ribbon element v is implied by (v^2) = S(Dr)Dr = (t^(-1)) (e^(-2 ϵ c)) (Dr^2) so choose v =(t^(-1/2))(e^(-ϵ c)) Dr , note Dr commutes with (e^(-ϵc)).
According to Ohtsuki p.72 read upside down, we should set the left-moving cup and cap to 1 and the right-moving cap nr should be v (Dr^(-1))=(t^(-1/2))(e^(-ϵ c)) and 
the right-moving cup ur should be Dr (v^(-1))=(t^(1/2))(e^(ϵ c)).

Logos

B[U@w,U@a]

(*η /: (η^(n_))/;n>1 :=0; *) 
η=((t+1)/(t-1))ϵ;
q = 1+η;
qI[k_]:=k(1+η(k-1)/2)//Expand
qFac[n_]:=n!(1+η (n-1)n/4)//Expand
InvqFac[n_]:=(1-η (n-1)n/4)/n!//Expand
qBin[n_,k_]:= Binomial[n,k](1+η k (n-k) /2)//Expand

(*Checking the commutation relation for powers of a,w*)
WmAn[m_,n_]:=Sum[(((1-t))^j)qBin[m,j]qBin[n,j]qFac[j]UU[(a^(n-j))]**(U[]+j η U[c])**UU[(w^(m-j))],{j,0,Min[m,n]}]
TestWmAn[m_,n_]:=-UU[(w^m),(a^n)]+WmAn[m,n]
TestWmAn[5,3]//Together

(*Guess qLogos first at q=1*)
ToDegh[F_,x_]:=Series[F/.{α->α h,δ->δ h,β->β h},{h,0,x}]
d=8;
LHS=Sum[(α^m)(δ^k)(β^n)InvqFac[m]InvqFac[k]InvqFac[n]WmAn[m+k,n+k],{m,0,d},{k,0,d-m},{n,0,d-m-k}]//Simp;
(*powers of nu as power series*)
nuA[z_]:=Sum[Binomial[z-1+x,x](((1-t))^x)(δ^x),{x,0,d}];
RHS = Sum[(((1-t))^j)nuA[m+k+n+j+1](α^(m+j))(δ^k)(β^(n+j))InvqFac[m]InvqFac[k]InvqFac[n]InvqFac[j]UU[(a^(n+k)),(w^(m+k))],{m,0,d},{k,0,d-m},{n,0,d-m-k},{j,0,d-m-n-k}]//Simp; 
ToDegh[(LHS-RHS)/.{ϵ->0}//Simp,8]

(*Now set up the LHS and RHS to find the Logos relating them.*)
d=11;
LHS=Sum[(α^m)(δ^k)(β^n)((WmAn[m+k,n+k])/(m!k!n!)),{m,0,d},{k,0,d-m},{n,0,d-m-k}]//Simp;
RHS =Sum[(((1-t))^j)(μ^(-(m+k+n+j+1)))(((α^(m+j))(δ^k)(β^(n+j)))/(m!k!n!j!))UU[(a^(n+k)),(w^(m+k))],{m,0,d},{k,0,d-m},{n,0,d-m-k},{j,0,d-m-n-k}];
CRHS = Sum[(((1-t))^j)(μ^(-(m+k+n+j+1)))(((α^(m+j))(δ^k)(β^(n+j)))/(m!n!k!j!))UU[(a^(n+k)),c,(w^(m+k))],{m,0,d},{k,0,d-m},{n,0,d-m-k},{j,0,d-m-n-k}]//Simp; 
μ = 1-(1-t)δ;

η

(*Here we guess and verify the Logos coefficient by coefficient*)
ToDegh[Coefficient[(-LHS+RHS+
(μ^(-4 ))(1-t)η (
(1-t)((1/2) (δ^2)(μ^2) + α β δ μ+(((α^2)(β^2))/4))RHS+
(μ^2)(δ μ+α β)CRHS+
β( δ μ+((α β )/2))  U[a]**RHS+
α( δ μ+((α β )/2) ) RHS**U[w]+
β δ (μ^2)   U[a]**CRHS+
α δ (μ^2)   CRHS**U[w]+
δ(1+μ)(μ δ+α β )U[a]**RHS**U[w]+
 (δ^2) (μ^2) U[a]**CRHS**U[w]+
(((β^2)δ)/4)(1+μ ) U[a,a]**RHS+
(((α^2)δ)/4)(1+μ )RHS**U[w,w]+
((β  (δ^2))/2) (1+2μ) U[a,a]**RHS**U[w]+
(( α  (δ^2))/2)(1+2μ) U[a]**RHS**U[w,w]+
 ((δ^3)/4)(1+3μ )U[a,a]**RHS**U[w,w])
),U[]],10]

(*Final check, put back ϵ.*)
ToDegh[(-LHS+RHS+
-(μ^(-4 ))(1+t)ϵ (
(1-t)((1/2) (δ^2)(μ^2) + α β δ μ+(((α^2)(β^2))/4))RHS+
(μ^2)(δ μ+α β)CRHS+
β( δ μ+((α β )/2))  U[a]**RHS+
α( δ μ+((α β )/2) ) RHS**U[w]+
β δ (μ^2)   U[a]**CRHS+
α δ (μ^2)   CRHS**U[w]+
δ(1+μ)(μ δ+α β )U[a]**RHS**U[w]+
 (δ^2) (μ^2) U[a]**CRHS**U[w]+
(((β^2)δ)/4)(1+μ ) U[a,a]**RHS+
(((α^2)δ)/4)(1+μ )RHS**U[w,w]+
((β  (δ^2))/2) (1+2μ) U[a,a]**RHS**U[w]+
(( α  (δ^2))/2)(1+2μ) U[a]**RHS**U[w,w]+
 ((δ^3)/4)(1+3μ )U[a,a]**RHS**U[w,w])
),10]//Simp