Pensieve header: A demo of the basic $C^\infty$ Lego blocks.

σ[x_]:=(Piecewise[{{(E^(-1/x)), x>0}, {0, x≤0}}])
Plot[σ[x],{x,-1,1}]

(Subscript[β, ϵ_])[x_]:=σ[ϵ+x]σ[ϵ-x]
Plot[(Subscript[β, 1])[x],{x,-2,2}]

(Subscript[β, a_,ϵ_])[z_]:=(Subscript[β, (ϵ^2)])[((Norm[z-a])^2)]
Plot3D[(Subscript[β, 0,1])[{x,y}],{x,-2,2},{y,-2,2},PlotPoints->100,PlotRange->All, Exclusions->None]

Z=NIntegrate[(Subscript[β, (1/2),(1/2)])[t],{t,0,1}];
θ[x_]:=(Z^(-1))NIntegrate[(Subscript[β, (1/2),(1/2)])[t],{t,0,x}]
Plot[θ[x],{x,-1,2}]

MandelbrotSetPlot[]

ϵ=0.2;
pts=Select[
Join@@Table[{x,y}, {x,-2,0.5,ϵ}, {y,-1,1,ϵ}],
MandelbrotSetMemberQ[#[[1]]+I#[[2]]]&
]

Graphics[pts/.{x_,y_}:>Disk[{x,y},ϵ]]

g[x_,y_]:=Sum[(Subscript[β, p,2ϵ])[{x,y}], {p,pts}];
Plot3D[g[x,y], {x,-2,0.5}, {y,-1,1}, PlotPoints -> 100, PlotRange->All, Exclusions->None]

f[x_,y_] := θ[(10^6)g[x,y]];
Plot3D[f[x,y], {x,-2,0.5}, {y,-1,1}, PlotPoints -> 100, PlotRange->All, Exclusions->None]

θ1=Interpolation[Table[{x,θ[x]},{x,0,1,0.01}]]

Plot[θ1[x],{x,-1,2}]

points = {{0,0},{1,1},{2,3},{3,4},{4,3},{5,0}};

f1[x_,y_] := θ1[3 (10^5)g[x,y]];
Plot3D[f1[x,y], {x,-2,0.5}, {y,-1,1}, PlotPoints -> 100, PlotRange->All, Exclusions->None]