Pensieve header: Three Peano curves.

?PeanoCurve

Peano Curve #1

Simplify[a+z+10(t-0.9)(-z)]

(Subscript[ϕ, 0,a_,_])[t_]:=ReIm[a];
(Subscript[ϕ, n_,a_,z_])[t_] := Which[
0≤t≤0.1, ReIm[a+10t z],
0.1≤t≤0.3, (Subscript[ϕ, n-1,a+z,z/2])[5(t-0.1)],
0.3≤t≤0.5, (Subscript[ϕ, n-1,a+z,I z/2])[5(t-0.3)],
0.5≤t≤0.7, (Subscript[ϕ, n-1,a+z,-z/2])[5(t-0.5)],
0.7≤t≤0.9, (Subscript[ϕ, n-1,a+z,-I z/2])[5(t-0.7)],
0.9≤t≤1, ReIm[a+10(1-t)z]
];
(Subscript[ϕ, n_])[t_]:=(Subscript[ϕ, n,0,0.5(1+I)])[t];

Table[t->(Subscript[ϕ, 1])[t], {t,0,1,0.05}]

ParametricPlot[(Subscript[ϕ, 1])[t], {t,0,1}, PlotRange ->All]

ParametricPlot[(Subscript[ϕ, 5])[t], {t,0,1}, PlotRange ->All, PlotPoints->10000]

(Subscript[ϕ, 0,a_,_])[t_]:=ReIm[a];
(Subscript[ϕ, n_,a_,z_])[t_] := Which[
0≤t≤0.1, ReIm[a+10t z],
0.1≤t≤0.3, (Subscript[ϕ, n-1,a+z,z/2.2])[5(t-0.1)],
0.3≤t≤0.5, (Subscript[ϕ, n-1,a+z,I z/2.2])[5(t-0.3)],
0.5≤t≤0.7, (Subscript[ϕ, n-1,a+z,-z/2.2])[5(t-0.5)],
0.7≤t≤0.9, (Subscript[ϕ, n-1,a+z,-I z/2.2])[5(t-0.7)],
0.9≤t≤1, ReIm[a+10(1-t)z]
];
(Subscript[ϕ, n_])[t_]:=(Subscript[ϕ, n,0,0.5(1+I)])[t];

ParametricPlot[(Subscript[ϕ, 5])[t], {t,0,1}, PlotRange ->All, PlotPoints->10000]

(Subscript[ϕ, 0,a_,_])[t_]:=ReIm[a];
(Subscript[ϕ, n_,a_,z_])[t_] := Which[
0≤t≤0.1, ReIm[a+10t z],
0.1≤t≤0.3, (Subscript[ϕ, n-1,a+z,z/2])[5(t-0.1)],
0.3≤t≤0.5, (Subscript[ϕ, n-1,a+z,I z/2])[5(t-0.3)],
0.5≤t≤0.7, (Subscript[ϕ, n-1,a+z,-z/2])[5(t-0.5)],
0.7≤t≤0.9, (Subscript[ϕ, n-1,a+z,-I z/2])[5(t-0.7)],
0.9≤t≤1, ReIm[a+10(1-t)z]
];
(Subscript[ϕ, n_])[t_]:=(Subscript[ϕ, n,0,0.5(1+I)])[t];
(Subscript[ϕ3, n_])[t_] := Append[(Subscript[ϕ, n])[t],t];

Table[t->(Subscript[ϕ3, 1])[t], {t,0,1,0.05}]

ParametricPlot3D[(Subscript[ϕ3, 4])[t], {t,0,1}, PlotRange ->All, PlotPoints->10000]

Peano Curve #2

Peano[0] = DLine[{{0,0},{1,1}}];
Peano[n_] := Peano[n-1] /. DLine[{{x0_,y0_},{x1_,y1_}}] :> {
dx=x1-x0; dy=y1-y0;
DLine[{{x0,y0}, {x0+1/2 dx, y0+1/2 dy}}],
Line[{{x0+1/2 dx, y0+1/2 dy}, {x0+1/2 dx, y0}}],
DLine[{{x0+1/2 dx, y0}, {x0+dx, y0+1/2 dy}}],
Line[{{x0+dx, y0+1/2 dy}, {x0, y0+1/2 dy}}],
DLine[{{x0, y0+1/2 dy}, {x0+1/2 dx, y0+dy}}],
Line[{{x0+1/2 dx, y0+dy}, {x0+1/2 dx, y0+1/2 dy}}],
DLine[{ {x0+1/2 dx, y0+1/2 dy},  {x0+dx, y0+dy}}]
};
GraphicsRow@Table[Graphics[Peano[n] /. DLine -> Line], {n, 0, 3}]

AlmostPeano[0] = DLine[{{0,0},{1,1}}];
AlmostPeano[n_] := AlmostPeano[n-1] /. DLine[{{x0_,y0_},{x1_,y1_}}] :> {
dx=x1-x0; dy=y1-y0;
DLine[{{x0,y0}, {x0+0.45 dx, y0+0.45 dy}}],
Line[{{x0+0.45 dx, y0+0.45 dy}, {x0+0.55 dx, y0}}],
DLine[{{x0+0.55 dx, y0}, {x0+dx, y0+0.45 dy}}],
Line[{{x0+dx, y0+0.45 dy}, {x0, y0+0.55 dy}}],
DLine[{{x0, y0+0.55 dy}, {x0+0.45 dx, y0+dy}}],
Line[{{x0+0.45 dx, y0+dy}, {x0+0.55 dx, y0+0.55 dy}}],
DLine[{ {x0+0.55 dx, y0+0.55 dy},  {x0+dx, y0+dy}}]
};
GraphicsRow@Table[Graphics[AlmostPeano[n] /. DLine -> Line], {n, 0, 3}]

Graphics[AlmostPeano[5] /. DLine -> Line]

Peano Curve #3

γ[t_List] := Prepend[
FromDigits[{#,0},2]& /@ Transpose[Partition[t,2]],
FromDigits[{2t,0},3]
];
Graphics3D[
Line[γ /@ Tuples[{0,1},14]],
ViewPoint->{-370.06,733.124,570.6},ViewVertical->{0.1792,0.789508,-0.599889}, Boxed -> False
]//Rasterize