Pensieve header: The main ${\mathfrak g}_0$ theorem.

Reminders

1. Fill out “Graduate Course Participation Form” (see http://drorbn.net/AcademicPensieve/Classes/17-1350-AKT/GCP.jpg, in time).
2. Make sure that you have Mathematica and that you play with these programs!
3. Change meeting time?

Theorem. R=(e^(h⊗l+e⊗f))=𝕆(exp(hl+(((e^h)-1)/h)ef|e⊗lf).

Representing (Subscript[g, 0])

Date: Sun, 23 May 1999 17:24:53 +0200 (MET DST)
From: Dylan Thurston <Dylan.Thurston@math.unige.ch>
To: Dror Bar-Natan <drorbn@math.huji.ac.il>
Subject: Oh, yeah...

Duflo had another possibly useful comment: he said that there is a simpler (non-trivial) algebra than sl_2, given by the relations (more or less)

        [x,y] = z
        [x,t] = x
        [y,t] = -y
        [t,z] = [x,z] = [y,z] = 0

I hope I got that right; it should be the Lie algebra of matrices

        0 x z
        0 t y
        0 0 0

He says that one can write down the exponential explicitly, that commutators very quickly go to zero, etc.  Apparently it plays the same role for reducible lie algebras that sl_2 plays for semi-simple ones. It’s worth thinking about.

Best,
        Dylan

ρh=(({{0, 0, -1}, {0, 0, 0}, {0, 0, 0}}));ρe=(({{0, 0, 0}, {0, 0, 1}, {0, 0, 0}})); ρl=(({{0, 0, 0}, {0, 1, 0}, {0, 0, 0}})); ρf=(({{0, 1, 0}, {0, 0, 0}, {0, 0, 0}})); 
B[x_?MatrixQ, y_?MatrixQ] := x.y-y.x;

MatrixForm /@ {B[ρe,ρl], B[ρf,ρl], B[ρe,ρf], B[ρh,ρe], B[ρh,ρl], B[ρh,ρf]}

Implementing (Subscript[g, 0])

PBWRule={e->1,l->2,f->3};
B[U@e,U@l]=-U@e;
B[U@f,U@l]=U@f;
B[U@e,U@f]=h U[];

$TD=3; ℏ /: (ℏ^(d_. ))/;d>$TD :=0;

x_⪯y_:=OrderedQ[{x,y}/.PBWRule]; x_≺y_:=!OrderedQ[{y,x}/.PBWRule];
Simp[ℰ_]:= Collect[ℰ, _U, Expand];

(Subscript[U, i_])[ℰ_] := ℰ /. {h->(Subscript[h, i]),t->(Subscript[t, i]), u_U :> Replace[u, x_ :> (Subscript[x, i]),1]};
B[U[(Subscript[(x_), i_])],U[(Subscript[(y_), i_])]]:=B[U[(Subscript[x, i])],U[(Subscript[y, i])]]=(Subscript[U, i])[B[U@x,U@y]];
B[U[(Subscript[(x_), i_])],U[(Subscript[(y_), j_])]] /; i=!=j := 0;
B[x_,x_]=0;
B[U[y_],U[x_]]:=B[U[y],U[x]]=Simp[-B[U[x],U[y]]];
B[x_,y_] := x**y-y**x;

Unprotect[NonCommutativeMultiply];
NonCommutativeMultiply[x_] := x;
0**_=_**0=0;
x_**U[]:=x; U[]**x_:=x;
(a_*x_U)**(b_*y_U) := If[a b === 0, 0, Simp[a b (x**y)]];
(a_*x_U)**y_ := Simp[a(x**y)]; x_**(a_*y_U) := Simp[a(x**y)];
(x_Plus)**y_ := (#**y)& /@ x; x_**(y_Plus) := (x**#)& /@ y;

U[xx___,x_] ** U[y_,yy___] := If[x⪯y,U[xx,x,y,yy], U@xx**(U@y**U@x+B[U@x,U@y])**U@yy];

UU[l___,((x_)^(n_)),r___]:= UU[l,Sequence@@Table[x,{n}],r];
UU[l___,1,r___]:= UU[l,r];
UU[]=U[];
UU[l_,r___]:=U[l]**UU[r];

UProducts[{},0]={UU[]};
UProducts[{},n_Integer] /; n>0 = {};
UProducts[{x_,xs___}, n_Integer] := Sort@Flatten@Table[UU[(x^k)]**u, {k,0,n},{u,UProducts[{xs},n-k]}];
UProducts[xs_List, k_Integer, n_Integer] := UProducts[Flatten@Table[(Subscript[x, j]), {x,xs}, {j,k}], n];
UProducts[any__, {n_}] := Flatten@Table[UProducts[any,k], {k,0,n}];

(Subscript[r, i_,j_]):=Simp[ℏ ((Subscript[h, i])UU[(Subscript[l, j])]+ UU[(Subscript[e, i]),(Subscript[f, j])])]

UExp[u_]:=Module[{s,t,k},
s=t=U[]; k=0;
While[k<20∧0=!=(t=t**u), s+=t/(++k)!];
Simp[s]];
(Subscript[R, i_,j_]):=UExp[(Subscript[r, i,j])];

m[i_,j_,k_][ℰ_] := Simp[ℰ /. {
u_U :> UU@@Join[DeleteCases[u,(Subscript[x_, i|j])],U@@Cases[u,(Subscript[x_, i]):>(Subscript[x, k])],U@@Cases[u,(Subscript[x_, j]):>(Subscript[x, k])]],
(Subscript[h, i|j])->(Subscript[h, k])}]

The Invariant of the Trefoil

; $TD=2;(Subscript[R, 4,1])**(Subscript[R, 2,5])**(Subscript[R, 6,3])

Timing[$TD=3; (Subscript[R, 4,1])**(Subscript[R, 2,5])**(Subscript[R, 6,3]) // m[1,2,1]//m[1,3,1]//m[1,4,1]//m[1,5,1]//m[1,6,1]]

Ordering Symbols

𝕆[poly_, specs___] := Module[{vs,us,z},
vs=Join@@(First /@ {specs});
us=Join@@({specs} /. (l_->s_) :> (l/.(Subscript[x_, i_]):>(Subscript[x, s])));
Simp@Total[CoefficientRules[Normal@Series[poly, {ℏ,0,$TD}], vs] /. (p_->c_) :> c UU@@((us^p))]
]

Theorem. R=(e^(h⊗l+e⊗f))=𝕆(exp(hl+(((e^h)-1)/h)ef|e⊗lf).
Brute Proof.

$TD=6;𝕆[Exp[ℏ (Subscript[h, 1])(Subscript[l, 2])+(((E^(ℏ (Subscript[h, 1])))-1)/(Subscript[h, 1]))(Subscript[e, 1])(Subscript[f, 2])], {(Subscript[e, 1])}->1,{(Subscript[l, 2]),(Subscript[f, 2])}->2]==(Subscript[R, 1,2])

Debts.
1. How does the 𝕆  program work?
2. Why is the above theorem true?
3. What do you do with it?

old above / new below

Theorem. R=(e^(h⊗l+e⊗f))=𝕆(exp(hl+(((e^h)-1)/h)ef|e⊗lf).
Gentler Proof, Presented Brutely.

MatrixForm /@ {MatrixExp[h ρl+e ρf], MatrixExp[h ρl].MatrixExp[(((E^h)-1)/h)e ρf]}

The Invariant of the Trefoil, Again

Timing[$TD=3;𝕆[Exp[ℏ h (Subscript[l, 1])+(((E^(ℏ h))-1)/h)(Subscript[e, 4])(Subscript[f, 1])+ℏ h (Subscript[l, 5])+(((E^(ℏ h))-1)/h)(Subscript[e, 2])(Subscript[f, 5])+ℏ h (Subscript[l, 3])+(((E^(ℏ h))-1)/h)(Subscript[e, 6])(Subscript[f, 3])], {(Subscript[l, 1]),(Subscript[f, 1]),(Subscript[e, 2]),(Subscript[l, 3]),(Subscript[f, 3]),(Subscript[e, 4]),(Subscript[l, 5]),(Subscript[f, 5]),(Subscript[e, 6])}->1] /. (Subscript[h, 1])->h]

Timing[$TD=5;𝕆[Exp[ℏ h (Subscript[l, 1])+(((E^(ℏ h))-1)/h)(Subscript[e, 4])(Subscript[f, 1])+ℏ h (Subscript[l, 5])+(((E^(ℏ h))-1)/h)(Subscript[e, 2])(Subscript[f, 5])+ℏ h (Subscript[l, 3])+(((E^(ℏ h))-1)/h)(Subscript[e, 6])(Subscript[f, 3])], {(Subscript[l, 1]),(Subscript[f, 1]),(Subscript[e, 2]),(Subscript[l, 3]),(Subscript[f, 3]),(Subscript[e, 4]),(Subscript[l, 5]),(Subscript[f, 5]),(Subscript[e, 6])}->1] /. (Subscript[h, 1])->h]

The Big (Subscript[𝔤, 0]) Lemma.

1. 𝕆((e^(γl+βe))|le)=𝕆((e^(γl+(e^γ)βe))|el).
2. 𝕆((e^(γl+βf))|fl)=𝕆((e^(γl+(e^γ)βf))|lf).
3. 𝕆((e^(βe+αf+δef))|fe)=𝕆(((νe)^(ν(-αβh+βe+αf+δef)))|ef), with ν=(((1+hδ))^(-1)).

Brute Proof.

$TD=3; 𝕆[(E^(ℏ γ (Subscript[l, 1])+β ℏ (Subscript[e, 1]))),{(Subscript[l, 1]),(Subscript[e, 1])}->1]

$TD=3; 𝕆[(E^(ℏ γ (Subscript[l, 1])+(E^(ℏ γ))β ℏ (Subscript[e, 1]))),{(Subscript[e, 1]),(Subscript[l, 1])}->1]

$TD=6; 𝕆[(E^(ℏ γ (Subscript[l, 1])+β ℏ (Subscript[e, 1]))),{(Subscript[l, 1]),(Subscript[e, 1])}->1]==𝕆[(E^(ℏ γ (Subscript[l, 1])+(E^(ℏ γ))β ℏ (Subscript[e, 1]))),{(Subscript[e, 1]),(Subscript[l, 1])}->1]

$TD=6; 𝕆[(E^(ℏ γ (Subscript[l, 1])+β ℏ (Subscript[f, 1]))),{(Subscript[f, 1]),(Subscript[l, 1])}->1]==𝕆[(E^(ℏ γ (Subscript[l, 1])+(E^(ℏ γ))β ℏ (Subscript[f, 1]))),{(Subscript[l, 1]),(Subscript[f, 1])}->1]

$TD=3; 𝕆[(E^(ℏ(β (Subscript[e, 1])+α (Subscript[f, 1])+δ (Subscript[e, 1])(Subscript[f, 1])))),{(Subscript[f, 1]),(Subscript[e, 1])}->1]

$TD=6; With[{ν=(((1+ℏ h δ))^(-1))}, 
𝕆[(E^(ℏ(β (Subscript[e, 1])+α (Subscript[f, 1])+δ (Subscript[e, 1])(Subscript[f, 1])))),{(Subscript[f, 1]),(Subscript[e, 1])}->1] == 𝕆[ν (E^(ℏ ν(-ℏ h α β+ β (Subscript[e, 1])+α (Subscript[f, 1])+δ (Subscript[e, 1])(Subscript[f, 1])))),{(Subscript[e, 1]),(Subscript[f, 1])}->1]  /. (Subscript[h, 1])->h
]

The Big (Subscript[g, 0]) Lemma. (again)
1. 𝕆((e^(γl+βe))|le)=𝕆((e^(γl+(e^γ)βe))|el).
2. 𝕆((e^(γl+βf))|fl)=𝕆((e^(γl+(e^γ)βf))|lf).
3. 𝕆((e^(βe+αf+δef))|fe)=𝕆(((νe)^(ν(-αβh+βe+αf+δef)))|ef), with ν=(((1+hδ))^(-1)).

Gentler Proofs of 1 & 2 and of 3 at δ=0.

MatrixForm /@ {MatrixExp[γ ρl].MatrixExp[β ρe], MatrixExp[(E^γ)β ρe].MatrixExp[γ ρl]}

MatrixForm /@ {MatrixExp[β ρf].MatrixExp[γ ρl], MatrixExp[γ ρl].MatrixExp[(E^γ)β ρf]}

MatrixForm /@ {MatrixExp[α ρf].MatrixExp[β ρe], MatrixExp[-α β ρh].MatrixExp[β ρe].MatrixExp[α ρf]}

The Main (Subscript[𝔤, 0]) Theorem.

Raw Version. The (Subscript[𝔤, 0]) invariant of any S-component tangle T can be written in the form Z(T)=𝕆(((ωe)^(L+Q))|(∏_(i∈S))(Subscript[e, i])(Subscript[l, i])(Subscript[f, i])), where ω is a scalar (meaning, a rational function in the variables (Subscript[h, i]) and their exponentials (Subscript[t, i])=(e^(Subscript[h, i]))), where L=∑(Subscript[a, ij])(Subscript[h, i])(Subscript[l, j]) is a balanced quadratic in the variables (Subscript[h, i]) and (Subscript[l, j]) with integer coefficients (Subscript[a, ij]) and where Q=∑(Subscript[b, ij])(Subscript[e, i])(Subscript[f, j]) is a balanced quadratic in the variables (Subscript[e, i]) and (Subscript[f, j]) with scalar coefficients (Subscript[b, ij]). Furthermore, after setting (Subscript[h, i])=h and (Subscript[t, i])=t for all i, the invariant Z(T) is poly-time computable.

Proof. Indeed, 
0. R=(e^(h⊗l+e⊗f))=𝕆(exp(hl+(((e^h)-1)/h)ef|e⊗lf),
1. 𝕆((e^(γl+βe))|le)=𝕆((e^(γl+(e^γ)βe))|el),
2. 𝕆((e^(γl+βf))|fl)=𝕆((e^(γl+(e^γ)βf))|lf),
3. 𝕆((e^(βe+αf+δef))|fe)=𝕆(((νe)^(ν(-αβh+βe+αf+δef)))|ef), with ν=(((1+hδ))^(-1)),
and the rest is straight-forward.

Polished Version. With (OverBar[e])=((((e^h)-1))/h)e, the (Subscript[𝔤, 0]) invariant of any S-component tangle T can be written in the form Z(T)=𝕆((ω^(-1))(e^(L+(ω^(-1))Q))|(∏_(i∈S))(Subscript[(OverBar[e]), i])(Subscript[l, i])(Subscript[f, i])), where ω is a scalar (meaning, a polynomial in the variables (Subscript[t, i])=(e^(Subscript[h, i]))), where L=∑(Subscript[a, ij])(Subscript[h, i])(Subscript[l, j]) is a balanced quadratic in the variables (Subscript[h, i]) and (Subscript[l, j]) with integer coefficients (Subscript[a, ij]) and where Q=∑(Subscript[b, ij])(Subscript[(OverBar[e]), i])(Subscript[f, j]) is a balanced quadratic in the variables (Subscript[(OverBar[e]), i]) and (Subscript[f, j]) with scalar coefficients (Subscript[b, ij]). Furthermore, after setting (Subscript[t, i])=t for all i, the invariant Z(T) is poly-time computable.

Debts.
1. Implement (and verify!).
2. Really prove part 3 of the big (Subscript[𝔤, 0])-lemma.