Why the Jones polynomial?

I’m sure there’s a great intuitive reason that the Jones polynomial is the way it is. But the description in class seemed incredibly arbitrary. Here’s what made sense to me:

(a) It makes sense to find an invariant by “resolving” every crossing until there are no crossings left
(b) Each crossing should be able to be resolved independently of all the others (i.e. order of resolving doesn’t matter), so multiplying together some information from each crossing makes sense
(c) Each crossing can be resolved in two ways, so the rule for resolving crossings should result in a sum of two distinct terms (one for each resolution), each with a monomial in q (a monomial so that by the end of this process, there will be a single term for every possible completed resolution of the knot)
(d) There are two distinct types of crossing that should be handled differently.
(e) When there are no crossings left, there is simply a disjoint union of loops; assigning a polynomial to unknots makes sense.

What did NOT make sense to me was the precise polynomials chosen. Why -(q^(-2))? Why q+1/q?

In this notebook, I will attempt to answer this question. Given four monomials a,b,c,d and and one polynomial u in the variable q, we define the “(a,b,c,d,u)-Jones polynomial” of a knot diagram (not necessarily of a knot!) to be the polynomial obtained by applying the Jones polynomial procedure, but 
- in the positive crossing case, replacing q and -(q^2) with a and b
- in the negative crossing case, replacing -(q^(-2)) and (q^(-1)) with c and d
- a completely resolved system of k unknots will have value (u^k)
Thus, the regular Jones polynomial is the (q,-(q^2),-(q^(-2)),(q^(-1)),q+(q^(-1)))-Jones polynomial.

Outline:
I. JonesPoly is an algorithm that takes a,b,c,d,u, and the crossings of a knot diagram (as in class) as input, and outputs the (a,b,c,d,u)-Jones polynomial of the knot diagram.
II. ReidemeisterInvariance is an algorithm that tests whether the (a,b,c,d,u)-Jones polynomial is invariant under Reidemeister moves, returning True or False
	a. Check it on the Jones polynomial
III. Iterate through all possible quintuples (a,b,c,d,u) with integer coefficients and check Reidemeister invariance. 

All three of these steps are done in a pretty brute-force, inefficient way, but hey, they work!

JonesPoly[a_,b_,c_,d_,u_,diag_]:=(
t2=diag/.{Xp[i_,j_,k_,l_] :> a*P[i,j] P[k,l]+b*P[i,l] P[j,k],
Xm[i_,j_,k_,l_] :>c*P[i,j] P[k,l]+d*P[i,l] P[j,k]};
t3=Expand[t2];
SetAttributes[P,Orderless];
t4=t3//.P[i_,j_] P[j_,k_]:>P[i,k];
t5=t4/.{P[i_,i_] :>u,P[i_,j_]^2 :>u};
Simplify[t5]
)

To test for Reidemeister Invariance, we need to be able to compare the (a,b,c,d,u)-Jones polynomials of any pair of knot diagrams that are one Reidemeister move apart. Without loss of generality, we can assume that the ONLY crossings involved in either diagram in the pair are crossings involved in the Reidemeister move (we will call such pairs R-simple pairs). Clearly, if the (a,b,c,d,u)-Jones polynomial is Reidemeister invariant, then it is Reidemeister invariant on R-simple pairs.

Conversely, suppose that the (a,b,c,d,u)-Jones polynomial is Reidemeister invariant on R-simple pairs. Consider any two knot diagrams separated by a Reidemeister move. We begin the Jones process on every crossing not involved in the Reidemeister move, which will give identical results at each step (modulo the Reidemeister move). Eventually, each diagram will have been reduced to a sum of terms, each consisting of a monomial in q and a knot diagram; the two sums will have an equal number of terms, and corresponding terms will have the same monomial in q and the diagrams will form an R-simple pair. Simply apply Reidemeister invariance on R-simple pairs to show that the (a,b,c,d,u)-Jones polynomials of the two knot diagrams are equal.

Further, we can assume that all segments of the knot diagram are involved in the Reidemeister move crossings. Otherwise, by the R-simple assumption, there must be unknots not involved in the move. But then every term in the final sum of resolved diagrams will have this unknot. Removing this unknot corresponds to dividing by u, preserving equality.

Thus, we simply enumerate all Reidemeister moves (counting orientation), and for each oriented move, consider all possible ways to link loose edges. These are found below. Thus, a (a,b,c,d,u)-Jones polynomial is invariant under Reidemeister moves if the following conditions are satisfied (corrections: the first two “coded” lines should have subscripts 1122 and 1221, respectively). Some of these may be redundant.

ReidemeisterInvariance[a_,b_,c_,d_,u_]:=(Jp[diag_]:=JonesPoly[a,b,c,d,u,diag];TrueQ[Simplify[Jp[Xp[1,1,2,2]]==u]&&
Simplify[Jp[Xm[1,2,2,1]]==u]&&
Simplify[Jp[Xm[2,3,4,1]Xp[4,3,2,1]]==u^2]&&
Simplify[Jp[Xp[3,4,1,2]Xm[1,4,3,2]]==u^2]&&
Simplify[Jp[Xp[2,3,4,1]Xm[4,3,2,1]]==u^2]&&
Simplify[Jp[Xp[2,3,1,1]Xm[4,3,2,4]]==u]&&
Simplify[Jp[Xp[2,4,5,1]Xm[5,4,3,1]Xm[3,6,6,2]]==Jp[Xm[5,2,3,5]Xm[3,1,6,4]Xp[6,1,2,4]]]&&
Simplify[Jp[Xm[4,1,2,4]Xm[6,5,3,1]Xp[3,5,6,2]]==Jp[Xp[6,2,3,4]Xm[3,1,6,4]Xm[2,5,5,1]]]&&
Simplify[Jp[Xp[5,1,2,6]Xp[4,4,3,1]Xp[3,5,6,2]]==Jp[Xp[4,2,3,5]Xp[3,1,6,6]Xp[2,4,5,1]]]&&
Simplify[Jp[Xm[2,6,6,1]Xp[4,4,3,1]Xm[3,5,5,2]]==Jp[Xm[4,2,3,6]Xp[3,1,5,6]Xm[5,1,2,4]]]&&
Simplify[Jp[Xm[2,6,5,1]Xp[4,4,3,1]Xm[3,5,6,2]]==Jp[Xm[4,2,3,5]Xp[3,1,6,6]Xm[5,1,2,4]]]&&
Simplify[Jp[Xm[2,6,5,1]Xp[5,4,3,1]Xm[3,4,6,2]]==Jp[Xm[5,2,3,5]Xp[3,1,6,6]Xm[4,1,2,4]]]&&
Simplify[Jp[Xm[2,5,5,1]Xp[6,4,3,1]Xm[3,4,6,2]]==Jp[Xm[6,2,3,5]Xp[3,1,6,5]Xm[4,1,2,4]]]&&
Simplify[Jp[Xm[2,4,5,1]Xp[5,4,3,1]Xm[3,6,6,2]]==Jp[Xm[5,2,3,5]Xp[3,1,6,4]Xm[6,1,2,4]]]]
)

Is the regular Jones polynomial a knot invariant?

ReidemeisterInvariance[q,-(q^2),-(q^(-2)),(q^(-1)),q+(q^(-1))]

Yes! Now let’s see if there are any others. We need to allow a,b,c,d to be any monomial in q (including negative exponents), and u to be any polynomial in q. This requires a lot of enumeration! Way too much for the computer to handle even if we just want to search around Jones territory. So for now we’ll search through the much smaller space satisfying:
- a,b,c,d, and u are all at worst quadratic
- all coefficients are -1, 0, or 1
- The more time I’ve spent with this, I’ve begun to realize that there should be some symmetry. That is, reflection (taking positive crossings to negative crossings) should correspond to replacing q by (q^(-1)).
- u should not be identically zero.

First we create a list that will generate lists {e,f,g,h,i,j,k} where e,f,g,h,i are -1, 0, or 1 (these will be coefficients) while j and k are between -2 and 2 (these will be exponents).

Possibilities[pos_]:=Module[{i,term,lst,max},lst={};If[pos≤5,max=1,max=2];
For[term=-max,term≤max,term++,
If[pos==1,lststarts={{}},lststarts=Possibilities[pos-1]];
For[i=1,i≤Length[lststarts],i++,
AppendTo[lststarts[[i]],term];
AppendTo[lst,lststarts[[i]]];
];
];
lst
]
thelist=Possibilities[7];

Now we simply run through all the options, generate the corresponding polynomials, and test Reidemeister invariance on each. (Warning: this takes a very long time to evaluate!)

For[i=1,i≤Length[thelist],i++,
jl=thelist[[i]];
If[Abs[jl[[3]]]+Abs[jl[[4]]]+Abs[jl[[5]]]>0,
a=jl[[1]]*q^jl[[6]];
b=jl[[2]]*q^jl[[7]];
c=jl[[2]]*q^-jl[[7]];
d=jl[[1]]*q^-jl[[6]];
u=jl[[3]]*q^-2+jl[[4]]*q^-1+jl[[5]]+jl[[4]]*q+jl[[3]]*q^2;
If[ReidemeisterInvariance[a,b,c,d,u],Print[{a,b,c,d,u}]];
];
]

Other than the Jones polynomial itself (and ones equivalent by some sort of symmetry or negation), one “new” type of invariant came out. At first this was exciting, but then I realized it was fairly uninteresting. In this one, every unknot has value ±1, and every crossing is resolved in only one way; the end result tells us that a large product of 1s and -1s is equal to ±1. Yes an invariant... no, not a useful one.

But then I realized that it’s not completely useless... when u=1 it’s useless, but when u=-1 this actually allows you to define a sort of parity of a knot. That is, pick a consistent method for resolving all crossings, possibly applying a minus sign at each step, and see whether the end result has an even or odd number of unknots. Perhaps not as powerful as the Jones polynomial, but I’m sure it’s an interesting invariant nonetheless!

In summary - after parity, the Jones polynomial is in some sense the next simplest polynomial knot invariant obtained using a crossing resolution process as described above. Unless I’m wrong about the necessity of symmetry, which is a possibility.