Pensieve header: The Logos in the vcw order, following Roland.

Implementing (Subscript[qg, 1])

ϵ /: (ϵ^2)=0; ϵ /: (ϵ^3)=0;
PBWRule={v->1,c->2,w->3};
B[U@c,U@w]=-(B[U@w,U@c]=U@w);
B[U@v,U@c]=-(B[U@c,U@v]=U@v);
B[U@w,U@v]=-(B[U@v,U@w]=(t-1) U[]+ϵ (t+1) U@c);

UU[l___,((x_)^(n_)),r___]:= UU[l,Sequence@@Table[x,{n}],r];
UU[l___,1,r___]:= UU[l,r];
UU[]=U[]; UU[l_,r___]:=U[l]**UU[r];(Subscript[U, i_])[ℰ_] := ℰ /. {b->(Subscript[b, i]),t->(Subscript[t, i]), u_U :> Replace[u, x_ :> (Subscript[x, i]),1]};

B[x_,x_]=0;
B[U[(Subscript[(x_), i_])],U[(Subscript[(y_), i_])]]:=B[U[(Subscript[x, i])],U[(Subscript[y, i])]]=(Subscript[U, i])[B[U@x,U@y]];
B[U[(Subscript[(x_), i_])],U[(Subscript[(y_), j_])]] /; i=!=j := 0;
B[x_,y_] := x**y-y**x;

x_⪯y_:=OrderedQ[{x,y}/.PBWRule]; x_≺y_:=!OrderedQ[{y,x}/.PBWRule];
Simp[ℰ_]:= Collect[ℰ, _U, Expand];

Unprotect[NonCommutativeMultiply];
NonCommutativeMultiply[x_] := x;
0**_=_**0=0;
x_**U[]:=x; U[]**x_:=x;
(a_*x_U)**(b_*y_U) := If[a b === 0, 0, Simp[a b (x**y)]];
(a_*x_U)**y_ := Simp[a(x**y)]; x_**(a_*y_U) := Simp[a(x**y)];
(x_Plus)**y_ := (#**y)& /@ x; x_**(y_Plus) := (x**#)& /@ y;
U[x_]**U[y_] := If[x≺y, U[x,y], U[y,x]+B[U@x,U@y]];
U[x_] ** U[y1_,yy__] := If[x⪯y1,U[x,y1,yy],(U@x**U@y1)**U@yy];
U[xx__,xn_]**U[yy__] := U@xx**(U@xn**U@yy);

U[l___,((x_)^(n_)),r___]:= U[l,Sequence@@Table[x,{n}],r];
U[l___,1,r___]:= U[l,r];

ToDegree[n_][ℰ_] := Simp[ℰ] /. a_.x_U :>Normal[Series[a,{ℏ,0,n}]]*x

LBasis[n_Integer] := LBasis[Range[n]];
LBasis[S_] := DeleteCases[0]@Module[{i,j,k,l}, SortBy[(# /. {ϵ->2,(Subscript[c, _])->2,(Subscript[v, _])->2,(Subscript[w, _])->2, U->Times})&][
Union@Flatten[{{U[],ϵ U[]},
Table[{U@(Subscript[c, i]),U@(Subscript[v, i]),U@(Subscript[w, i]),ϵ U@(Subscript[c, i]),ϵ U@(Subscript[v, i]),ϵ U@(Subscript[w, i])}, {i,S}],
Table[{U[(Subscript[v, i]),(Subscript[w, j])],ϵ U[(Subscript[v, i]),(Subscript[w, j])],ϵ U@@Sort@{(Subscript[c, i]),(Subscript[c, j])},ϵ U[(Subscript[v, j]),(Subscript[c, i])],ϵ U[(Subscript[c, i]),(Subscript[w, j])]}, {i,S}, {j,S}],
Table[{ϵ U[(Subscript[v, j]),(Subscript[c, i]),(Subscript[w, k])],ϵ U@@Sort@{(Subscript[v, i]),(Subscript[v, j]),(Subscript[w, k])},ϵ U@@Sort@{(Subscript[v, i]),(Subscript[w, j]),(Subscript[w, k])}}, {i,S}, {j,S},{k,S}],
Table[ϵ U@@Sort@{(Subscript[v, i]),(Subscript[v, j]),(Subscript[w, k]),(Subscript[w, l])}, {i,S}, {j,S},{k,S},{l,S}] }]
]]

BLBasis[n_Integer] := BLBasis[Range[n]];
BLBasis[S_] := DeleteCases[0]@Module[{i,j,k,l}, SortBy[(# /. {ϵ->2,(Subscript[c, _])->2,(Subscript[v, _])->2,(Subscript[w, _])->2, U->Times})&][
Union@Flatten[{{U[],ϵ U[]},
Table[{U@(Subscript[c, i]),ϵ U@(Subscript[c, i])}, {i,S}],
Table[{U[(Subscript[v, i]),(Subscript[w, j])],ϵ U[(Subscript[v, i]),(Subscript[w, j])],ϵ U@@Sort@{(Subscript[c, i]),(Subscript[c, j])}}, {i,S}, {j,S}],
Table[{ϵ U[(Subscript[v, j]),(Subscript[c, i]),(Subscript[w, k])]}, {i,S}, {j,S},{k,S}],
Table[ϵ U@@Sort@{(Subscript[v, i]),(Subscript[v, j]),(Subscript[w, k]),(Subscript[w, l])}, {i,S}, {j,S},{k,S},{l,S}] }]
]]

𝕆[n_, poly_, specs___] := Module[{vs,us},
vs=Join@@(First /@ {specs});
us=Join@@({specs} /. (l_->s_) :> (l/.(Subscript[x_, i_]):>(Subscript[x, s])));
Total[CoefficientRules[Normal@Series[poly, {ℏ,0,n}], vs] /. (p_->c_) :> c UU@@((us^p))]]

Testing (Subscript[g, 1])

B[U@(Subscript[v, 1]),U@(Subscript[w, 1])]

LBasis[2]

bas=LBasis[2];Table[B[x,y]+B[y,x], {x,bas},{y,bas}] //Flatten//Union

bas=LBasis[2]; Timing[
Table[
{x,y,z}=xyz;
Simp[B[B[x,y],z]+B[B[y,z],x]+B[B[z,x],y]],
{xyz, Subsets[bas,{3}]}
] //Flatten//Union
]

Testing bi-local exponential relations in (Subscript[g, 0])

c Relations.

𝕆[3, (E^(ℏ(γ (Subscript[c, 0])+β (Subscript[v, 0])))),{(Subscript[v, 0]),(Subscript[c, 0])}->0]

𝕆[3, (E^(ℏ(γ (Subscript[c, 0])+(E^(-ℏ γ))β (Subscript[v, 0])))),{(Subscript[c, 0]),(Subscript[v, 0])}->0]

With[{n=7}, Simp[𝕆[n, (E^(ℏ(γ (Subscript[c, 0])+β (Subscript[v, 0])))),{(Subscript[v, 0]),(Subscript[c, 0])}->0]==𝕆[n, (E^(ℏ(γ (Subscript[c, 0])+(E^(-ℏ γ))β (Subscript[v, 0])))),{(Subscript[c, 0]),(Subscript[v, 0])}->0]]]

With[{n=7}, Simp[𝕆[n, (E^(ℏ(γ (Subscript[c, 0])+ℏ β (Subscript[w, 0])))),{(Subscript[w, 0]),(Subscript[c, 0])}->0]==𝕆[n, (E^(ℏ(γ (Subscript[c, 0])+ℏ (E^(ℏ γ))β (Subscript[w, 0])))),{(Subscript[c, 0]),(Subscript[w, 0])}->0]]]

v-w Relations.

Λ[α_,β_,δ_,μ_ ,v_,c_,w_,t_]:=-((1+t)/4)(4v c w (δ^2) (μ^2)+δ (1+μ)((w^2) (α^2)+ (v^2) (β^2) )+ (v^2) (w^2) (δ^3) (1+3 μ)+(1-t)(2(((α β+δ μ))^2)-(α^2) (β^2))+2(α β+2δ μ+ v w (δ^2) (1+2 μ)+2c  δ (μ^2))(w α +v β )+ 4(c (μ^2)+v w δ (1+μ) )(α β+δ μ) );

With[{n=7},ToDegree[n][
(𝕆[n,(E^(ℏ(α (Subscript[w, 0])+β (Subscript[v, 0])+δ (Subscript[v, 0])(Subscript[w, 0])))),{(Subscript[w, 0]),(Subscript[v, 0])}->0])-𝕆[n,(μ^(-1))(1+ϵ (μ^(-4))Λ[ℏ α,ℏ β,ℏ δ,μ,(Subscript[v, 0]),(Subscript[c, 0]),(Subscript[w, 0]),(Subscript[t, 0])])(E^(((ℏ^2)(1-(Subscript[t, 0]))α β+ℏ α (Subscript[w, 0])+ℏ β (Subscript[v, 0])+ℏ δ (Subscript[v, 0])(Subscript[w, 0]))/μ))/. μ-> 1-(1-(Subscript[t, 0]))ℏ δ,{(Subscript[v, 0]),(Subscript[c, 0]),(Subscript[w, 0])}->0]
]]

FullSimplify[Λ[α,β,δ,μ,v,c,w,t]]