Pensieve header: Testing notebook for Scatter and Glow in OneCo.

In the U(T)U(H) conventions.

SetDirectory["C:\\drorbn\\AcademicPensieve\\2016-02"];
<< SnG.m

Bases

UUBasis[{1,2},{3,4},f]

Meta-associativity for tm

((# // tm[s1,s2,s1] // tm[s1,s3,s1]) == (# // tm[s2,s3,s2] // tm[s1,s2,s1]))& /@ UUBasis[{s1,s2,s3,s4},{s5,s6},f] // Union

Meta-associativity for hm

((# // hm[s1,s2,s1] // hm[s1,s3,s1]) == (# // hm[s2,s3,s2] // hm[s1,s2,s1]))& /@ UUBasis[{s5,s6},{s1,s2,s3,s4},f] // Union

Compatibility between tm and hts

(((# // tm[s1,s2,s1] // hts[s4,s1]) == (# // hts[s4,s1] // hts[s4,s2] // tm[s1,s2,s1]))& /@ UUBasis[{s1,s2,s3},{s4,s5},f]) // Union

Compatibility between hm and hts

(((# // hm[s1,s2,s1] // hts[s1,s4]) == (# // hts[s2,s4] // hts[s1,s4] // hm[s1,s2,s1]))& /@ UUBasis[{s4,s5},{s1,s2,s3},f]) // Union

Meta-associativity for dm

((# // dm[s1,s2,s1] // dm[s1,s3,s1]) == (# // dm[s2,s3,s2] // dm[s1,s2,s1]))& /@ UUBasis[{s1,s2,s3,s4},f] // Union

Meta-AS and meta-Jacobi for tb

tbAS[u_,v_] := tb[s0][u, v] + tb[s0][v,u];
DeleteCases[
Flatten[Outer[
{##} -> tbAS[##]&,
UUBasis[{s0,s1},{s1,s2}, f], UUBasis[{s0,s2},{s3,s4},f]
]],
_ -> UU[0]
]

tbJacobi[u_,v_,w_] := tb[s0][u, tb[s0][v,w]] + tb[s0][v, tb[s0][w,u]] + tb[s0][w, tb[s0][u,v]];
DeleteCases[
Flatten[Outer[
{##} -> tbJacobi[##]&,
UUBasis[{s0,s1},{s1,s2}, f], UUBasis[{s0,s2},{s3,s4},g], UUBasis[{s0,s3},{s5,s6},h]
]],
_ -> UU[0]
]

Compatibility of tb and tm

tbtm[u_,v_] := Plus[
tb[s1][u,tσ[s2,-s2][v]] // tm[s2,-s2,s2],
-tb[s1][u,tσ[s2,-s2][v]] // tm[-s2,s2,s2],
-tb[s2][u,tσ[s1,-s1][v]] // tm[s1,-s1,s1],
tb[s2][u,tσ[s1,-s1][v]] // tm[-s1,s1,s1]
];
DeleteCases[
Flatten[Outer[
{##} -> tbtm[##]&,
UUBasis[{s1,s2,s3},{s1,s2}, f], UUBasis[{s1,s2,s4},{s3,s4},f]
]],
_ -> UU[0]
]

Meta-AS and meta-Jacobi for hb

hbAS[u_,v_] := hb[s0][u, v] + hb[s0][v,u];
DeleteCases[
Flatten[Outer[
{##} -> hbAS[##]&,
UUBasis[{s1,s2},{0,1}, f], UUBasis[{s3,s4},{s0,s2},g]
]],
_ -> UU[0]
]

hbJacobi[u_,v_,w_] := hb[s0][u, hb[s0][v,w]] + hb[s0][v, hb[s0][w,u]] + hb[s0][w, hb[s0][u,v]];
DeleteCases[
Flatten[Outer[
{##} -> hbJacobi[##]&,
UUBasis[{s1,s2},{s0,s1}, f], UUBasis[{s3,s4},{s0,s2},g], UUBasis[{s5,s6},{s0,s3},h]
]],
_ -> UU[0]
]

Compatibility of tb and tm

hbhm[u_,v_] := Plus[
hb[s1][u,hσ[s2,-s2][v]] // hm[s2,-s2,s2],
-hb[s1][u,hσ[s2,-s2][v]] // hm[-s2,s2,s2],
-hb[s2][u,hσ[s1,-s1][v]] // hm[s1,-s1,s1],
hb[s2][u,hσ[s1,-s1][v]] // hm[-s1,s1,s1]
];
DeleteCases[
Flatten[Outer[
{##} -> hbhm[##]&,
UUBasis[{s1,s2},{s1,s2,s3}, f], UUBasis[{s3,s4},{s1,s2,s4},g]
]],
_ -> UU[0]
]

Meta-Jacobi for thb/tb and for thb/hb

tthJacobi[u_,v_,w_] := Plus[
-thb[s0,s0][tb[s0][u,v],w]+tb[s0][thb[s0,s0][u,w],v]-thb[s0,s0][v, thb[s0,s0][u,w]]+tb[s0][u,thb[s0,s0][v,w]]+thb[s0,s0][u,thb[s0,s0][v,w]]
];
DeleteCases[
Flatten[Outer[
{##} -> tthJacobi[##]&,
UUBasis[{s0,s1},{s1,s2}, f], UUBasis[{s0,s2},{s3,s4},g], UUBasis[{s3,s4},{s0,s5},h]
]],
_ -> UU[0]
]

thhJacobi[u_,v_,w_] := Plus[
-thb[s0,s0][u,hb[s0][v,w]]+hb[s0][thb[s0,s0][u,v],w]+thb[s0,s0][thb[s0,s0][u,v], w]+hb[s0][v,thb[s0,s0][u,w]]-thb[s0,s0][thb[s0,s0][u,w],v]
];
DeleteCases[
Flatten[Outer[
{##} -> thhJacobi[##]&,
UUBasis[{s0,s1},{s1,s2}, f], UUBasis[{s2,s3},{s0,s3},g], UUBasis[{s4,s5},{s0,s4},h]
]],
_ -> UU[0]
]

Meta-AS and meta-Jacobi for db

dbAS[u_,v_] := db[s0][u, v] + db[s0][v,u];
DeleteCases[
Flatten[Outer[
{##} -> dbAS[##]&,
UUBasis[{s0,s1,s2}, f], UUBasis[{s0,s3,s4},g]
]],
_ -> UU[0]
]

dbJacobi[u_,v_,w_] := db[s0][u, db[s0][v,w]] + db[s0][v, db[s0][w,u]] + db[s0][w, db[s0][u,v]];
DeleteCases[
Flatten[Outer[
{##} -> dbJacobi[##]&,
UUBasis[{s0,s1,s2}, f], UUBasis[{s0,s3,s4},g], UUBasis[{s0,s5,s6},h]
]],
_ -> UU[0]
]

AS and Jacobi for bb

bb4=bb[s1,s2,s3,s4];
bbAS[u_,v_] := bb4[u, v] + bb4[v,u];
DeleteCases[
Flatten[Outer[
{##} -> bbAS[##]&,
UUBasis[{s1,s2}, f], UUBasis[{s1,s2},g]
]],
_ -> UU[0]
]

bb[S_List] := Module[{w,bar0,t},
w=#2//dσ[S,bar/@S];
Sum[
t=db[S[[k]]][#1,w // dσ[bar[S[[k]]], S[[k]]]];
Do[t=t//dm[bar[S[[i]]], S[[i]], S[[i]]], {i,1,k-1}];
Do[t=t//dm[S[[i]], bar[S[[i]]], S[[i]]], {i,k+1,Length@S}];
t,
{k,Length@S}
]
]&
bb[S___] := bb[{S}]

bb2=bb[1,2];
bbAS[u_,v_] := bb2[u, v] + bb2[v,u];
{u,v}={UU[a[f[(Subscript[b, 2])],1,1]],UU[a[1,2,1]]};
bbAS[u,v]

bb3=bb[1,2,3];
bbJacobi[u_,v_,w_] := bb3[u, bb3[v,w]] + bb3[v, bb3[w,u]] + bb3[w, bb3[u,v]];
DeleteCases[
Flatten[Outer[
{##} -> bbJacobi[##]&,
UUBasis[3, f], UUBasis[3,g], UUBasis[3,h]
]],
_ -> UU[0]
]

ct (contract) poperties

Outer[
Equal[
ct[#1 // tm[1,2,1], #2],
ct[#1, #2] // tm[1,2,1]
]&,
UUBasis[{1,2,3},{0,1},f], UUBasis[{0,4},{2,3},g]
] //Flatten// Union

Outer[
{#1,#2} -> Equal[
ct[#1 // hm[1,2,1], #2],
ct[#1, #2] // hm[1,2,1]
]&,
UUBasis[{1,2},{0,1,2,3},f], UUBasis[{0,4},{4,5},g]
] //Flatten // DeleteCases[#, _->True]&

Outer[
{#1,#2} -> Equal[
ct[#1, #2 // hm[2,3,2]],
ct[#1, #2] // hm[2,3,2]
]&,
UUBasis[{1,2},{0,1},f], UUBasis[{0,3},{2,3,4},g]
] //Flatten // DeleteCases[#, _->True]&

Outer[
{#1,#2} -> Equal[
ct[#1, #2 // tm[3,4,3]],
ct[#1, #2] // tm[3,4,3]
]&,
UUBasis[{1,2},{0,1},f], UUBasis[{0,3,4,5},{2,3},g]
] //Flatten // DeleteCases[#, _->True]&